[gn build] Add build file for DebugInfoPDBTests

[thakis]

Summary

I'm pretty unhappy this patch. DebugInfoPDBTests uses an API that requires some magic txt file to be next to the unit test executable that stores the absolute path to the LLVM source root. The choices here are:

1. Don't use the unittest() template for DebugInfoPDBTests and set output_dir for unit tests in two places (the gni file for every test but this one, and the BUILD.gn file for this specific test).

2. Add a 3rd unittest_foo() template variation for this one test.

I went with the former, and added a comment to the template to look out for this.

(The CMake build has the same issue.)

[thakis]

It looks like I need to add knowledge about the tests going in target_out_dir in two other places, so I think I'll remove the new template() here and put this directly in the build file of the test, and just add a comment in the gni file along the lines of If you change output_dir, look through git grep target_out_dir '*/unittests/*'`.

[thakis]

no template

[phosek]

LGTM but don't forget to update the message.

llvm/utils/gn/secondary/llvm/unittests/BUILD.gn

 import("//llvm/lib/Target/targets.gni")
 
 group("unittests") {
   deps = [
     "ADT:ADTTests",
     "Analysis:AnalysisTests",
     "AsmParser:AsmParserTests",
     "BinaryFormat:BinaryFormatTests",
     "Bitcode:BitcodeTests",
     "CodeGen:CodeGenTests",
     "CodeGen/GlobalISel:GlobalISelTests",
     "DebugInfo/CodeView:DebugInfoCodeViewTests",
     "DebugInfo/DWARF:DebugInfoDWARFTests",
     "DebugInfo/MSF:DebugInfoMSFTests",
-
-    # FIXME: Add.
-    #"DebugInfo/PDB:DebugInfoPDBTests",
+    "DebugInfo/PDB:DebugInfoPDBTests",
     "Demangle:DemangleTests",
 
     # FIXME: Add.
     #"ExecutionEngine:ExecutionEngineTests",
     #"ExecutionEngine/MCJIT:MCJITTests",
     #"ExecutionEngine/Orc:OrcJITTests",
     "FuzzMutate:FuzzMutateTests",
     "IR:IRTests",
     "LineEditor:LineEditorTests",
     "Linker:LinkerTests",
     "MC:MCTests",
     "MI:MITests",
     "Object:ObjectTests",
     "ObjectYAML:ObjectYAMLTests",
     "OptRemarks:OptRemarksTests",
     "Option:OptionTests",
-    "OptRemarks:OptRemarksTests",
-    "Option:OptionTests",
 
     # FIXME: Add.
     #"Passes:PluginsTests",
     "ProfileData:ProfileDataTests",
     "Support:SupportTests",
 
     # FIXME: Add.
     #"Support/DynamicLibrary:DynamicLibraryTests",
     "TextAPI:TextAPITests",
     "Transforms/IPO:IPOTests",
     "Transforms/Scalar:ScalarTests",
     "Transforms/Utils:UtilsTests",
     "Transforms/Vectorize:VectorizeTests",
     "XRay:XRayTests",
     "tools/llvm-cfi-verify:CFIVerifyTests",
     "tools/llvm-exegesis:LLVMExegesisTests",
   ]
 
-  # Target-dependend unit tests.
+  # Target-dependent unit tests.
   # FIXME: This matches how they are set up in the cmake build,
   # but if we disable an arch after building with it on, this
   # setup leaves behind stale executables.
   # FIXME: Add AArch64, ARM these once the Targets exist.
   #if (llvm_build_AArch64) {
   #deps += [
   #"Target/AArch64:AArch64Tests",
   #"tools/llvm-exegesis/AArch64:LLVMExegesisAArch64Tests",

llvm/utils/gn/secondary/llvm/unittests/DebugInfo/PDB/BUILD.gn

+import("//llvm/utils/unittest/unittest.gni")
+
+unittest("DebugInfoPDBTests") {
+  deps = [
+    "//llvm/lib/DebugInfo/CodeView",
+    "//llvm/lib/DebugInfo/MSF",
+    "//llvm/lib/DebugInfo/PDB",
+    "//llvm/lib/Testing/Support",
+  ]
+  sources = [
+    "HashTableTest.cpp",
+    "NativeSymbolReuseTest.cpp",
+    "PDBApiTest.cpp",
+    "StringTableBuilderTest.cpp",
+  ]
+
+  # DebugInfoPDBTests uses llvm::getInputFileDirectory(), which expects
+  # a file called llvm.srcdir.txt next to the test executable that contains
+  # the path of the source directory (which contains this file).
+  # lit doesn't change the cwd while running googletests, so the cwd isn't
+  # well-defined. This means this has to be an absolute path.
+  # FIXME: This doesn't work with swarming. This should really be a data
+  # dependency, and the cwd while tests requiring input files run should
+  # be required to be some fixed directory.
+  # FIXME: Also, the GN way is to write this file at build time. But since
+  # there's only one use of this, and since this is a pattern that hopefully
+  # will disappear again, and since it doesn't have any measurable performance
+  # hit, write the file at GN time.
+  # Note: This line here implicitly depends on unittest() setting output_dir to
+  # target_out_dir.
+  write_file("$target_out_dir/llvm.srcdir.txt", rebase_path("."))
+}

llvm/utils/gn/secondary/llvm/utils/unittest/unittest.gni

executable(target_name) {
     # below foo_obj_root/unittests. As long as the BUILD.gn files processing
     # the lit.site.cfg.py.in files match the output dir here, it doesn't
     # matter all that much where the unit test binaries go, with the weak
     # constraints that test binaries of different projects should go in
     # different folders, and that it's not too difficult to manually
     # run the unit test binary if necessary. Using target_out_dir here
     # means that //clang/unittests/Format gets its binary in
     # out/gn/obj/clang/unittests/Format/FormatTests, which seems fine.
+    #
+    # If you change output_dir here, look through
+    # `git grep target_out_dir '*/unittests/*'` and update those too.
     output_dir = target_out_dir
     deps += [ "//llvm/utils/unittest/UnitTestMain" ]
     testonly = true
   }
 }
 
 set_defaults("unittest") {
   configs = shared_binary_target_configs