[mlir][sparse] Add 3-dimensional sparse tensor multiplication integration test

[vmrajas]

Summary

This diff adds an integration test which does element wise multiplication for two sparse 3-d tensors of size 3x3x5

[aartbik]

Thanks for your first test!

mlir/test/Integration/Dialect/SparseTensor/CPU/sparse_tensor_mul.mlir

26

line up arga/argb?

43

no double empty line

105

since you use dump only once, why not inline the code
(becomes shorter too, due to sharing some of the constants)?

[vmrajas]

Address comments

[vmrajas]

Thanks for the quick review. I have addressed your comments.

mlir/test/Integration/Dialect/SparseTensor/CPU/sparse_tensor_mul.mlir

105

Aah. I was planning on adding another test related to tensor ops (maybe addition).
I will add dump as a function while writing that test then.

[vmrajas]

mlir/test/Integration/Dialect/SparseTensor/CPU/sparse_tensor_mul.mlir

99

I am not completely sure if we have to do this (as we were doing in dump) and whether we should dealloc m1 as well.

[aartbik]

mlir/test/Integration/Dialect/SparseTensor/CPU/sparse_tensor_mul.mlir

99

Always run with sanitizer on before submitting.
Config:

...
 -DLLVM_USE_SANITIZER=Address \
 -DMLIR_INCLUDE_INTEGRATION_TESTS=ON \
...

[aartbik]

mlir/test/Integration/Dialect/SparseTensor/CPU/sparse_tensor_mul.mlir

99

and the answer is, yes, at the moment, but there is a pending change by Matthias which will have to change this (since we are migrating to the much better OneShot bufferization)

[vmrajas]

mlir/test/Integration/Dialect/SparseTensor/CPU/sparse_tensor_mul.mlir

99

Got it. I ran with the sanitizer and it showed no errors.

[aartbik]

mlir/test/Integration/Dialect/SparseTensor/CPU/sparse_tensor_mul.mlir

95

why not use default_value here too, and get rid of the %d0
the -1 also jumps out a bit more than the 0 value

99

Make sure to rebase with main and retest sanitizer test run, since the OneShot bufferization just went in. After that, ship it!

[vmrajas]

Rebase and address comments

mlir/test/Integration/Dialect/SparseTensor/CPU/sparse_tensor_mul.mlir

+// RUN: mlir-opt %s --sparse-compiler | \
+// RUN: mlir-cpu-runner \
+// RUN:  -e entry -entry-point-result=void  \
+// RUN:  -shared-libs=%mlir_integration_test_dir/libmlir_c_runner_utils%shlibext | \
+// RUN: FileCheck %s
+
+#ST = #sparse_tensor.encoding<{dimLevelType = ["compressed", "compressed", "compressed"]}>
+
+//
+// Trait for 3-d tensor element wise multiplication.
+//
+#trait_mul = {
+  indexing_maps = [
+    affine_map<(i,j,k) -> (i,j,k)>,  // A (in)
+    affine_map<(i,j,k) -> (i,j,k)>,  // B (in)
+    affine_map<(i,j,k) -> (i,j,k)>   // X (out)
+  ],
+  iterator_types = ["parallel", "parallel", "parallel"],
+  doc = "X(i,j,k) = A(i,j,k) * B(i,j,k)"
+}
+
+module {
+  // Multiplies two 3-d sparse tensors element-wise into a new sparse tensor.
+  func.func @tensor_mul(%arga: tensor<?x?x?xf64, #ST>,
+                        %argb: tensor<?x?x?xf64, #ST>) -> tensor<?x?x?xf64, #ST> {
+    %c0 = arith.constant 0 : index
+    %c1 = arith.constant 1 : index
+    %c2 = arith.constant 2 : index
+    %d0 = tensor.dim %arga, %c0 : tensor<?x?x?xf64, #ST>
+    %d1 = tensor.dim %arga, %c1 : tensor<?x?x?xf64, #ST>
+    %d2 = tensor.dim %arga, %c2 : tensor<?x?x?xf64, #ST>
+    %xt = bufferization.alloc_tensor(%d0, %d1, %d2) : tensor<?x?x?xf64, #ST>
+    %0 = linalg.generic #trait_mul
+       ins(%arga, %argb: tensor<?x?x?xf64, #ST>, tensor<?x?x?xf64, #ST>)
+        outs(%xt: tensor<?x?x?xf64, #ST>) {
+        ^bb(%a: f64, %b: f64, %x: f64):
+          %1 = arith.mulf %a, %b : f64
+          linalg.yield %1 : f64
+    } -> tensor<?x?x?xf64, #ST>
+    return %0 : tensor<?x?x?xf64, #ST>
+  }
+
+  // Driver method to call and verify tensor multiplication kernel.
+  func.func @entry() {
+    %c0 = arith.constant 0 : index
+    %default_val = arith.constant -1.0 : f64
+
+    // Setup sparse tensor A
+    %ta = arith.constant dense<
+      [ [ [1.0, 0.0, 0.0, 0.0, 0.0 ],
+          [0.0, 0.0, 0.0, 0.0, 0.0 ],
+          [1.2, 0.0, 3.5, 0.0, 0.0 ] ],
+        [ [0.0, 0.0, 0.0, 0.0, 0.0 ],
+          [0.0, 0.0, 0.0, 0.0, 0.0 ],
+          [0.0, 0.0, 0.0, 0.0, 0.0 ] ],
+        [ [2.0, 0.0, 0.0, 0.0, 0.0 ],
+          [0.0, 0.0, 0.0, 0.0, 0.0 ],
+          [0.0, 0.0, 4.0, 0.0, 0.0 ]] ]> : tensor<3x3x5xf64>
+
+    // Setup sparse tensor B
+    %tb = arith.constant dense<
+      [ [ [0.0, 0.0, 0.0, 0.0, 4.0 ],
+          [0.0, 0.0, 0.0, 0.0, 0.0 ],
+          [2.0, 0.0, 1.0, 0.0, 0.0 ] ],
+        [ [0.0, 0.0, 0.0, 0.0, 9.0 ],
+          [0.0, 0.0, 0.0, 0.0, 0.0 ],
+          [0.0, 7.0, 0.0, 0.0, 0.0 ] ],
+        [ [1.0, 0.0, 0.0, 0.0, 0.0 ],
+          [0.0, 0.0, 0.0, 0.0, 0.0 ],
+          [0.0, 0.0, 2.0, 0.0, 0.0 ]] ]> : tensor<3x3x5xf64>
+
+    %sta = sparse_tensor.convert %ta : tensor<3x3x5xf64> to tensor<?x?x?xf64, #ST>
+    %stb = sparse_tensor.convert %tb : tensor<3x3x5xf64> to tensor<?x?x?xf64, #ST>
+
+
+    // Call sparse tensor multiplication kernel.
+    %0 = call @tensor_mul(%sta, %stb)
+      : (tensor<?x?x?xf64, #ST>, tensor<?x?x?xf64, #ST>) -> tensor<?x?x?xf64, #ST>
+
+    // Verify results
+    //
+    // CHECK:      ( 2.4, 3.5, 2, 8, -1, -1, -1, -1 )
+    // CHECK-NEXT: ( ( ( 0, 0, 0, 0, 0 ), ( 0, 0, 0, 0, 0 ), ( 2.4, 0, 3.5, 0, 0 ) ),
+    // CHECK-SAME: ( ( 0, 0, 0, 0, 0 ), ( 0, 0, 0, 0, 0 ), ( 0, 0, 0, 0, 0 ) ),
+    // CHECK-SAME: ( ( 2, 0, 0, 0, 0 ), ( 0, 0, 0, 0, 0 ), ( 0, 0, 8, 0, 0 ) ) )
+    //
+    %m1 = sparse_tensor.values %0  : tensor<?x?x?xf64, #ST> to memref<?xf64>
+    %v1 = vector.transfer_read %m1[%c0], %default_val: memref<?xf64>, vector<8xf64>
+    vector.print %v1 : vector<8xf64>
+
+    // Print %0 in dense form.
+    %d0 = arith.constant 0.0 : f64
+    %dt = sparse_tensor.convert %0 : tensor<?x?x?xf64, #ST> to tensor<?x?x?xf64>
+    %m2 = bufferization.to_memref %dt : memref<?x?x?xf64>
+    %v2 = vector.transfer_read %m2[%c0, %c0, %c0], %d0: memref<?x?x?xf64>, vector<3x3x5xf64>
+    vector.print %v2 : vector<3x3x5xf64>
+
+    // Release the resources.
+    memref.dealloc %m2 : memref<?x?x?xf64>
+    sparse_tensor.release %sta : tensor<?x?x?xf64, #ST>
+    sparse_tensor.release %stb : tensor<?x?x?xf64, #ST>
+    sparse_tensor.release %0  : tensor<?x?x?xf64, #ST>
+    return
+  }
+}