This is an archive of the discontinued LLVM Phabricator instance.

Differential D55593

[gn build] Add all non-test build files for lld
ClosedPublic

Authored by thakis on Dec 11 2018, 7:37 PM.

Details

Reviewers
phosek
• espindola
Commits
rG7a1ba21fab48: [gn build] Add all non-test build files for lld
rL348945: [gn build] Add all non-test build files for lld
Summary

Mostly boring. Version.inc.in processing has a potentially interesting part which I've punted on for now (LLD_REVISION and LLD_REPOSITORY are set to empty strings for now).

lld now builds in the gn build. But no symlinks to it are created yet, so it can't be meaningfully run yet.

Diff Detail

Event Timeline

thakis created this revision.Dec 11 2018, 7:37 PM
Herald added a reviewer: • espindola. · View Herald TranscriptDec 11 2018, 7:37 PM
Herald added subscribers: jfb, fedor.sergeev, aheejin and 3 others. · View Herald Transcript
thakis edited the summary of this revision. (Show Details)Dec 12 2018, 7:52 AM
phosek accepted this revision.Dec 12 2018, 9:36 AM

LGTM

llvm/utils/gn/secondary/lld/COFF/BUILD.gn
10

Now that I'm looking at this, it feels a bit awkward for lld config to be in //llvm/... rather than something like //lld:lld_config.

This revision is now accepted and ready to land.Dec 12 2018, 9:36 AM
thakis marked an inline comment as done.Dec 12 2018, 9:59 AM

Thanks!

llvm/utils/gn/secondary/lld/COFF/BUILD.gn
10

Happy to move it in a follow-up, just say the word :-)

Closed by commit rL348945: [gn build] Add all non-test build files for lld (authored by nico). · Explain WhyDec 12 2018, 10:03 AM
This revision was automatically updated to reflect the committed changes.

Revision Contents

PathSize
llvm/
utils/
gn/
build/
libs/
xml/
2 lines
secondary/
2 lines
lld/
COFF/
44 lines
Common/
28 lines
ELF/
64 lines
MinGW/
21 lines
include/
lld/
Common/
26 lines
lib/
Core/
20 lines
Driver/
24 lines
ReaderWriter/
17 lines
MachO/
33 lines
YAML/
11 lines
tools/
lld/
16 lines
wasm/
32 lines

Diff 177816

llvm/utils/gn/build/libs/xml/BUILD.gn

Context not available.
defines = [ "LLVM_LIBXML2_ENABLED" ] defines = [ "LLVM_LIBXML2_ENABLED" ]
libs = [ "xml2" ] libs = [ "xml2" ]
if (host_os == "mac") { if (host_os == "mac") {
include_dirs = [ "$mac_sdk/usr/include/libxml2" ] include_dirs = [ "$mac_sdk_path/usr/include/libxml2" ]
} else { } else {
include_dirs = [ "/usr/include/libxml2" ] include_dirs = [ "/usr/include/libxml2" ]
} }
Context not available.

llvm/utils/gn/secondary/BUILD.gn

group("default") { group("default") {
deps = [ deps = [
"//llvm/lib/LTO", "//lld/tools/lld",
"//llvm/tools/llc", "//llvm/tools/llc",
"//llvm/tools/llvm-undname", "//llvm/tools/llvm-undname",
] ]

llvm/utils/gn/secondary/lld/COFF/BUILD.gn

  • This file was added.
import("//llvm/utils/TableGen/tablegen.gni")
tablegen("Options") {
visibility = [ ":COFF" ]
args = [ "-gen-opt-parser-defs" ]
}
static_library("COFF") {
output_name = "lldCOFF"
configs += [ "//llvm/utils/gn/build:lld_code" ]
phosekUnsubmitted
Not Done
ReplyInline Actions

Now that I'm looking at this, it feels a bit awkward for lld config to be in //llvm/... rather than something like //lld:lld_config.

phosek: Now that I'm looking at this, it feels a bit awkward for lld config to be in `//llvm/...`…
thakisAuthorUnsubmitted
Done
ReplyInline Actions

Happy to move it in a follow-up, just say the word :-)

thakis: Happy to move it in a follow-up, just say the word :-)
deps = [
":Options",
"//lld/Common",
"//llvm/lib/BinaryFormat",
"//llvm/lib/DebugInfo/CodeView",
"//llvm/lib/DebugInfo/MSF",
"//llvm/lib/DebugInfo/PDB",
"//llvm/lib/IR",
"//llvm/lib/LTO",
"//llvm/lib/MC",
"//llvm/lib/Object",
"//llvm/lib/Option",
"//llvm/lib/Support",
"//llvm/lib/Target:TargetsToBuild",
"//llvm/lib/ToolDrivers/llvm-lib:LibDriver",
"//llvm/lib/WindowsManifest",
]
sources = [
"Chunks.cpp",
"DLL.cpp",
"Driver.cpp",
"DriverUtils.cpp",
"ICF.cpp",
"InputFiles.cpp",
"LTO.cpp",
"MapFile.cpp",
"MarkLive.cpp",
"MinGW.cpp",
"PDB.cpp",
"SymbolTable.cpp",
"Symbols.cpp",
"Writer.cpp",
]
}

llvm/utils/gn/secondary/lld/Common/BUILD.gn

  • This file was added.
static_library("Common") {
output_name = "lldCommon"
configs += [ "//llvm/utils/gn/build:lld_code" ]
public_deps = [
# public_dep because public header Version.h includes generated Version.inc.
"//lld/include/lld/Common:version",
]
deps = [
"//llvm/lib/CodeGen",
"//llvm/lib/Demangle",
"//llvm/lib/IR",
"//llvm/lib/MC",
"//llvm/lib/Option",
"//llvm/lib/Support",
"//llvm/lib/Target",
]
sources = [
"Args.cpp",
"ErrorHandler.cpp",
"Memory.cpp",
"Reproduce.cpp",
"Strings.cpp",
"TargetOptionsCommandFlags.cpp",
"Threads.cpp",
"Timer.cpp",
"Version.cpp",
]
}

llvm/utils/gn/secondary/lld/ELF/BUILD.gn

  • This file was added.
import("//llvm/utils/TableGen/tablegen.gni")
tablegen("Options") {
visibility = [ ":ELF" ]
args = [ "-gen-opt-parser-defs" ]
}
static_library("ELF") {
output_name = "lldELF"
configs += [ "//llvm/utils/gn/build:lld_code" ]
deps = [
":Options",
"//lld/Common",
"//llvm/lib/BinaryFormat",
"//llvm/lib/DebugInfo/DWARF",
"//llvm/lib/IR",
"//llvm/lib/LTO",
"//llvm/lib/MC",
"//llvm/lib/Object",
"//llvm/lib/Option",
"//llvm/lib/Support",
"//llvm/lib/Target:TargetsToBuild",
]
include_dirs = [ "." ]
sources = [
"AArch64ErrataFix.cpp",
"Arch/AArch64.cpp",
"Arch/AMDGPU.cpp",
"Arch/ARM.cpp",
"Arch/AVR.cpp",
"Arch/Hexagon.cpp",
"Arch/Mips.cpp",
"Arch/MipsArchTree.cpp",
"Arch/PPC.cpp",
"Arch/PPC64.cpp",
"Arch/RISCV.cpp",
"Arch/SPARCV9.cpp",
"Arch/X86.cpp",
"Arch/X86_64.cpp",
"CallGraphSort.cpp",
"DWARF.cpp",
"Driver.cpp",
"DriverUtils.cpp",
"EhFrame.cpp",
"Filesystem.cpp",
"ICF.cpp",
"InputFiles.cpp",
"InputSection.cpp",
"LTO.cpp",
"LinkerScript.cpp",
"MapFile.cpp",
"MarkLive.cpp",
"OutputSections.cpp",
"Relocations.cpp",
"ScriptLexer.cpp",
"ScriptParser.cpp",
"SymbolTable.cpp",
"Symbols.cpp",
"SyntheticSections.cpp",
"Target.cpp",
"Thunks.cpp",
"Writer.cpp",
]
}

llvm/utils/gn/secondary/lld/MinGW/BUILD.gn

  • This file was added.
import("//llvm/utils/TableGen/tablegen.gni")
tablegen("Options") {
visibility = [ ":MinGW" ]
args = [ "-gen-opt-parser-defs" ]
}
static_library("MinGW") {
output_name = "lldMinGW"
configs += [ "//llvm/utils/gn/build:lld_code" ]
deps = [
":Options",
"//lld/COFF",
"//lld/Common",
"//llvm/lib/Option",
"//llvm/lib/Support",
]
sources = [
"Driver.cpp",
]
}

llvm/utils/gn/secondary/lld/include/lld/Common/BUILD.gn

  • This file was added.
import("//llvm/version.gni")
action("version") {
script = "//llvm/utils/gn/build/write_cmake_config.py"
sources = [
"Version.inc.in",
]
outputs = [
"$target_gen_dir/Version.inc",
]
args = [
"-o",
rebase_path(outputs[0], root_out_dir),
rebase_path(sources[0], root_out_dir),
"LLD_VERSION=$llvm_version",
"LLD_VERSION_MAJOR=$llvm_version_major",
"LLD_VERSION_MINOR=$llvm_version_minor",
# FIXME: Real values for these:
"LLD_REVISION=",
"LLD_REPOSITORY=",
]
}

llvm/utils/gn/secondary/lld/lib/Core/BUILD.gn

  • This file was added.
static_library("Core") {
output_name = "lldCore"
configs += [ "//llvm/utils/gn/build:lld_code" ]
deps = [
"//llvm/lib/BinaryFormat",
"//llvm/lib/MC",
"//llvm/lib/Support",
"//llvm/utils/gn/build/libs/pthread",
]
sources = [
"DefinedAtom.cpp",
"Error.cpp",
"File.cpp",
"LinkingContext.cpp",
"Reader.cpp",
"Resolver.cpp",
"SymbolTable.cpp",
"Writer.cpp",
]
}

llvm/utils/gn/secondary/lld/lib/Driver/BUILD.gn

  • This file was added.
import("//llvm/utils/TableGen/tablegen.gni")
tablegen("DarwinLdOptions") {
visibility = [ ":Driver" ]
args = [ "-gen-opt-parser-defs" ]
}
static_library("Driver") {
output_name = "lldDriver"
configs += [ "//llvm/utils/gn/build:lld_code" ]
deps = [
":DarwinLdOptions",
"//lld/Common",
"//lld/lib/Core",
"//lld/lib/ReaderWriter",
"//lld/lib/ReaderWriter/MachO",
"//lld/lib/ReaderWriter/YAML",
"//llvm/lib/Option",
"//llvm/lib/Support",
]
sources = [
"DarwinLdDriver.cpp",
]
}

llvm/utils/gn/secondary/lld/lib/ReaderWriter/BUILD.gn

  • This file was added.
static_library("ReaderWriter") {
output_name = "lldReaderWriter"
configs += [ "//llvm/utils/gn/build:lld_code" ]
deps = [
"//lld/lib/Core",
"//llvm/lib/Object",
"//llvm/lib/Support",
]
sources = [
"FileArchive.cpp",
]
# FIXME:
# if (is_msvc) {
# cflags = [ "-wd4062" ]
# }
}

llvm/utils/gn/secondary/lld/lib/ReaderWriter/MachO/BUILD.gn

  • This file was added.
static_library("MachO") {
output_name = "lldMachO"
configs += [ "//llvm/utils/gn/build:lld_code" ]
deps = [
"//lld/lib/Core",
"//lld/lib/ReaderWriter/YAML",
"//llvm/lib/DebugInfo/DWARF",
"//llvm/lib/Demangle",
"//llvm/lib/Object",
"//llvm/lib/Support",
]
sources = [
"ArchHandler.cpp",
"ArchHandler_arm.cpp",
"ArchHandler_arm64.cpp",
"ArchHandler_x86.cpp",
"ArchHandler_x86_64.cpp",
"CompactUnwindPass.cpp",
"GOTPass.cpp",
"LayoutPass.cpp",
"MachOLinkingContext.cpp",
"MachONormalizedFileBinaryReader.cpp",
"MachONormalizedFileBinaryWriter.cpp",
"MachONormalizedFileFromAtoms.cpp",
"MachONormalizedFileToAtoms.cpp",
"MachONormalizedFileYAML.cpp",
"ObjCPass.cpp",
"ShimPass.cpp",
"StubsPass.cpp",
"TLVPass.cpp",
"WriterMachO.cpp",
]
}

llvm/utils/gn/secondary/lld/lib/ReaderWriter/YAML/BUILD.gn

  • This file was added.
static_library("YAML") {
output_name = "lldYAML"
configs += [ "//llvm/utils/gn/build:lld_code" ]
deps = [
"//lld/lib/Core",
"//llvm/lib/Support",
]
sources = [
"ReaderWriterYAML.cpp",
]
}

llvm/utils/gn/secondary/lld/tools/lld/BUILD.gn

  • This file was added.
# FIXME: Set up symlinks pointing to lld.
executable("lld") {
configs += [ "//llvm/utils/gn/build:lld_code" ]
deps = [
"//lld/COFF",
"//lld/ELF",
"//lld/MinGW",
"//lld/lib/Driver",
"//lld/wasm",
"//llvm/lib/Support",
]
sources = [
"lld.cpp",
]
}

llvm/utils/gn/secondary/lld/wasm/BUILD.gn

  • This file was added.
import("//llvm/utils/TableGen/tablegen.gni")
tablegen("Options") {
visibility = [ ":wasm" ]
args = [ "-gen-opt-parser-defs" ]
}
static_library("wasm") {
output_name = "lldWasm"
configs += [ "//llvm/utils/gn/build:lld_code" ]
deps = [
":Options",
"//lld/Common",
"//llvm/lib/BinaryFormat",
"//llvm/lib/Demangle",
"//llvm/lib/IR",
"//llvm/lib/Object",
"//llvm/lib/Option",
]
sources = [
"Driver.cpp",
"InputChunks.cpp",
"InputFiles.cpp",
"LTO.cpp",
"MarkLive.cpp",
"OutputSections.cpp",
"SymbolTable.cpp",
"Symbols.cpp",
"Writer.cpp",
"WriterUtils.cpp",
]
}