[ConstantFold][InstSimplify] Pre-commit tests for D144445 (NFC)

[khei4]

Summary

Restructure and add tests for patterned aggregates load folding.

D144445

alive proofs: https://alive2.llvm.org/ce/z/mWB6if

[khei4]

(Just for double-checking) I moved the tests because some cases are affected by the target endian.

[khei4]

fixed typo

[khei4]

do forgotten updates (sorry for being noisy). I'll land by myself.

[StephenFan]

llvm/test/Transforms/InstSimplify/load-patterned-aggregates.ll

30

I think this case can also be folded since every i32 values in constarray are same. Is there a TODO missing?
And BTW, we can also fold it if replace [4 x i32] with [4 x i16]. See https://alive2.llvm.org/ce/z/xt2c2z .

[khei4]

missed to tie with the actual commit https://reviews.llvm.org/rG0eb45cd081e4ad8c496aa8358082ef2644c6a50f. abandon this revision.

llvm/test/Transforms/InstSimplify/load-patterned-aggregates.ll

30

I think this case can also be folded since every i32 values in constarray are same. Is there a TODO missing?

Thank you! Right. But sorry, I failed to tie the actual commit with this revision, already committed by https://reviews.llvm.org/rG0eb45cd081e4ad8c496aa8358082ef2644c6a50f so I'll implement in https://reviews.llvm.org/D144445.

And BTW, we can also fold it if replace [4 x i32] with [4 x i16]. See https://alive2.llvm.org/ce/z/xt2c2z .

That's also right. Thank you for comments!

[khei4]

now I noticed the need to add Differential Revision: <URL> https://llvm.org/docs/Phabricator.html#committing-a-change

llvm/test/Transforms/InstSimplify/load-patterned-aggregates.ll

+; NOTE: Assertions have been autogenerated by utils/update_test_checks.py
+; RUN: opt < %s -passes=instsimplify -S | FileCheck %s
+
+@constzeroarray = internal constant [4 x i32] zeroinitializer
+
+@constarray = internal constant [8 x i8]  c"\01\00\01\00\01\00\01\00", align 4
+@conststruct = internal constant <{[8 x i8]}>  <{[8 x i8] c"\01\00\01\00\01\00\01\00"}>, align 4
+
+define i32 @load_gep_const_zero_array(i64 %idx) {
+; CHECK-LABEL: @load_gep_const_zero_array(
+; CHECK-NEXT:    ret i32 0
+;
+  %gep = getelementptr inbounds [4 x i32], ptr @constzeroarray, i64 0, i64 %idx
+  %load = load i32, ptr %gep
+  ret i32 %load
+}
+
+define i8 @load_i8_multi_gep_const_zero_array(i64 %idx1, i64 %idx2) {
+; CHECK-LABEL: @load_i8_multi_gep_const_zero_array(
+; CHECK-NEXT:    ret i8 0
+;
+  %gep1 = getelementptr inbounds i8, ptr @constzeroarray, i64 %idx1
+  %gep = getelementptr inbounds i8, ptr %gep1, i64 %idx2
+  %load = load i8, ptr %gep
+  ret i8 %load
+}
+
+
+define i32 @load_gep_const_patterned_array(i64 %idx) {
+; CHECK-LABEL: @load_gep_const_patterned_array(
+; CHECK-NEXT:    [[GEP:%.*]] = getelementptr inbounds [4 x i32], ptr @constpatterned, i64 0, i64 [[IDX:%.*]]
+; CHECK-NEXT:    [[LOAD:%.*]] = load i32, ptr [[GEP]], align 4
+; CHECK-NEXT:    ret i32 [[LOAD]]
+;
+  %gep = getelementptr inbounds [4 x i32], ptr @constpatterned, i64 0, i64 %idx
+  %load = load i32, ptr %gep
+  ret i32 %load
+}
+
+define i8 @load_i8_multi_gep_const_array(i64 %idx1, i64 %idx2) {
+; CHECK-LABEL: @load_i8_multi_gep_const_array(
+; CHECK-NEXT:    [[GEP1:%.*]] = getelementptr inbounds i8, ptr @constpatterned, i64 [[IDX1:%.*]]
+; CHECK-NEXT:    [[GEP:%.*]] = getelementptr inbounds i8, ptr [[GEP1]], i64 [[IDX2:%.*]]
+; CHECK-NEXT:    [[LOAD:%.*]] = load i8, ptr [[GEP]], align 1
+; CHECK-NEXT:    ret i8 [[LOAD]]
+;
+  %gep1 = getelementptr inbounds i8, ptr @constpatterned, i64 %idx1
+  %gep = getelementptr inbounds i8, ptr %gep1, i64 %idx2
+  %load = load i8, ptr %gep
+  ret i8 %load
+}
+
+; TODO: this should be ret i8 1
+define i8 @gep_load_i8_align2(i64 %idx){
+; CHECK-LABEL: @gep_load_i8_align2(
+; CHECK-NEXT:    [[TMP1:%.*]] = getelementptr inbounds i8, ptr @constarray, i64 [[IDX:%.*]]
+; CHECK-NEXT:    [[TMP2:%.*]] = load i8, ptr [[TMP1]], align 2
+; CHECK-NEXT:    ret i8 [[TMP2]]
+;
+  %1 = getelementptr inbounds i8, ptr @constarray, i64 %idx
+  %2 = load i8, ptr %1, align 2
+  ret i8 %2
+}
+
+; can't be folded
+define i8 @gep_load_i8_align1(i64 %idx){
+; CHECK-LABEL: @gep_load_i8_align1(
+; CHECK-NEXT:    [[TMP1:%.*]] = getelementptr inbounds i8, ptr @constarray, i64 [[IDX:%.*]]
+; CHECK-NEXT:    [[TMP2:%.*]] = load i8, ptr [[TMP1]], align 1
+; CHECK-NEXT:    ret i8 [[TMP2]]
+;
+  %1 = getelementptr inbounds i8, ptr @constarray, i64 %idx
+  %2 = load i8, ptr %1, align 1
+  ret i8 %2
+}
+
+; TODO: this should be ret i8 65537 on the case for little endian
+define i32 @gep_i32_load_i32_align2(i64 %idx){
+; CHECK-LABEL: @gep_i32_load_i32_align2(
+; CHECK-NEXT:    [[TMP1:%.*]] = getelementptr inbounds i32, ptr @constarray, i64 [[IDX:%.*]]
+; CHECK-NEXT:    [[TMP2:%.*]] = load i32, ptr [[TMP1]], align 4
+; CHECK-NEXT:    ret i32 [[TMP2]]
+;
+  %1 = getelementptr inbounds i32, ptr @constarray, i64 %idx
+  %2 = load i32, ptr %1, align 4
+  ret i32 %2
+}
+
+; TODO: this should be ret i8 65537 on the case for little endian
+define i32 @gep_i32_load_i32_align2_struct(i64 %idx){
+; CHECK-LABEL: @gep_i32_load_i32_align2_struct(
+; CHECK-NEXT:    [[TMP1:%.*]] = getelementptr inbounds i32, ptr @conststruct, i64 [[IDX:%.*]]
+; CHECK-NEXT:    [[TMP2:%.*]] = load i32, ptr [[TMP1]], align 4
+; CHECK-NEXT:    ret i32 [[TMP2]]
+;
+  %1 = getelementptr inbounds i32, ptr @conststruct, i64 %idx
+  %2 = load i32, ptr %1, align 4
+  ret i32 %2
+}
+
+; can't be folded
+define i32 @gep_i8_load_i32_align1(i64 %idx){
+; CHECK-LABEL: @gep_i8_load_i32_align1(
+; CHECK-NEXT:    [[TMP1:%.*]] = getelementptr inbounds i8, ptr @constarray, i64 [[IDX:%.*]]
+; CHECK-NEXT:    [[TMP2:%.*]] = load i32, ptr [[TMP1]], align 1
+; CHECK-NEXT:    ret i32 [[TMP2]]
+;
+  %1 = getelementptr inbounds i8, ptr @constarray, i64 %idx
+  %2 = load i32, ptr %1, align 1
+  ret i32 %2
+}
+
+; can't be folded
+define i32 @gep_i8_load_i32_align1_struct(i64 %idx){
+; CHECK-LABEL: @gep_i8_load_i32_align1_struct(
+; CHECK-NEXT:    [[TMP1:%.*]] = getelementptr inbounds i8, ptr @conststruct, i64 [[IDX:%.*]]
+; CHECK-NEXT:    [[TMP2:%.*]] = load i32, ptr [[TMP1]], align 1
+; CHECK-NEXT:    ret i32 [[TMP2]]
+;
+  %1 = getelementptr inbounds i8, ptr @conststruct, i64 %idx
+  %2 = load i32, ptr %1, align 1
+  ret i32 %2
+}
+; TODO: This could be folded but need to see GEP source types
+define i32 @gep_i16_load_i32_align1(i64 %idx){
+; CHECK-LABEL: @gep_i16_load_i32_align1(
+; CHECK-NEXT:    [[TMP1:%.*]] = getelementptr inbounds i16, ptr @constarray, i64 [[IDX:%.*]]
+; CHECK-NEXT:    [[TMP2:%.*]] = load i32, ptr [[TMP1]], align 2
+; CHECK-NEXT:    ret i32 [[TMP2]]
+;
+  %1 = getelementptr inbounds i16, ptr @constarray, i64 %idx
+  %2 = load i32, ptr %1, align 1
+  ret i32 %2
+}

llvm/test/Transforms/InstSimplify/load.ll

 ; NOTE: Assertions have been autogenerated by utils/update_test_checks.py
 ; RUN: opt < %s -passes=instsimplify -S | FileCheck %s
 
 @zeroinit = constant {} zeroinitializer
 @poison = constant {} poison
 
-@constzeroarray = internal constant [4 x i32] zeroinitializer
-
-@constarray = internal constant [4 x i32] [i32 1, i32 1, i32 1, i32 1]
-@constarrayi8 = internal constant [2 x i8] [i8 1, i8 1]
-
 define i32 @crash_on_zeroinit() {
 ; CHECK-LABEL: @crash_on_zeroinit(
 ; CHECK-NEXT:    ret i32 poison
 ;
   %load = load i32, ptr @zeroinit
   ret i32 %load
 }
 

 ; This does an out of bounds load from the global constant
 define <3 x float> @load_vec3() {
 ; CHECK-LABEL: @load_vec3(
 ; CHECK-NEXT:    ret <3 x float> poison
 ;
   %1 = load <3 x float>, ptr getelementptr inbounds (<3 x float>, ptr @constvec, i64 1)
   ret <3 x float> %1
 }
-
-define i32 @load_gep_const_zero_array(i64 %idx) {
-; CHECK-LABEL: @load_gep_const_zero_array(
-; CHECK-NEXT:    ret i32 0
-;
-  %gep = getelementptr inbounds [4 x i32], ptr @constzeroarray, i64 0, i64 %idx
-  %load = load i32, ptr %gep
-  ret i32 %load
-}
-
-define i8 @load_i8_multi_gep_const_zero_array(i64 %idx1, i64 %idx2) {
-; CHECK-LABEL: @load_i8_multi_gep_const_zero_array(
-; CHECK-NEXT:    ret i8 0
-;
-  %gep1 = getelementptr inbounds i8, ptr @constzeroarray, i64 %idx1
-  %gep = getelementptr inbounds i8, ptr %gep1, i64 %idx2
-  %load = load i8, ptr %gep
-  ret i8 %load
-}
-
-define i32 @load_gep_const_array(i64 %idx) {
-; CHECK-LABEL: @load_gep_const_array(
-; CHECK-NEXT:    [[GEP:%.*]] = getelementptr inbounds [4 x i32], ptr @constarray, i64 0, i64 [[IDX:%.*]]
-; CHECK-NEXT:    [[LOAD:%.*]] = load i32, ptr [[GEP]], align 4
-; CHECK-NEXT:    ret i32 [[LOAD]]
-;
-  %gep = getelementptr inbounds [4 x i32], ptr @constarray, i64 0, i64 %idx
-  %load = load i32, ptr %gep
-  ret i32 %load
-}
-
-define i8 @load_i8_multi_gep_const_array(i64 %idx1, i64 %idx2) {
-; CHECK-LABEL: @load_i8_multi_gep_const_array(
-; CHECK-NEXT:    [[GEP1:%.*]] = getelementptr inbounds i8, ptr @constarrayi8, i64 [[IDX1:%.*]]
-; CHECK-NEXT:    [[GEP:%.*]] = getelementptr inbounds i8, ptr [[GEP1]], i64 [[IDX2:%.*]]
-; CHECK-NEXT:    [[LOAD:%.*]] = load i8, ptr [[GEP]], align 1
-; CHECK-NEXT:    ret i8 [[LOAD]]
-;
-  %gep1 = getelementptr inbounds i8, ptr @constarrayi8, i64 %idx1
-  %gep = getelementptr inbounds i8, ptr %gep1, i64 %idx2
-  %load = load i8, ptr %gep
-  ret i8 %load
-}