gn build: Add support for building the AArch64 LSE builtins.

[thakis]

llvm/utils/gn/secondary/compiler-rt/lib/builtins/BUILD.gn

38

This angers and confuses the sync script as-is:

% llvm/utils/gn/build/sync_source_lists_from_cmake.py 
[gn build] Port a72d462eb9b9 -- https://reviews.llvm.org/rGa72d462eb9b9
  llvm/utils/gn/secondary/compiler-rt/lib/builtins/BUILD.gn
   remove:
    aarch64/lse.S

[pcc]

Stop sync_source_lists_from_cmake.py from finding the reference to the source file

[pcc]

llvm/utils/gn/secondary/compiler-rt/lib/builtins/BUILD.gn

38

Ah, found a way to silence that.

[thakis]

clever!

llvm/utils/gn/secondary/compiler-rt/lib/builtins/BUILD.gn

 import("//compiler-rt/target.gni")
 import("//llvm/utils/gn/build/buildflags.gni")
 
 declare_args() {
   # Skip the atomic builtin (should normally be provided by a shared library).
   compiler_rt_exclude_atomic_builtin = true
 }
 
+lse_targets = []
+
+if (current_cpu == "arm64") {
+  foreach(pat,
+          [
+            "cas",
+            "swp",
+            "ldadd",
+            "ldclr",
+            "ldeor",
+            "ldset",
+          ]) {
+    foreach(size,
+            [
+              "1",
+              "2",
+              "4",
+              "8",
+              "16",
+            ]) {
+      foreach(model,
+              [
+                "1",
+                "2",
+                "3",
+                "4",
+              ]) {
+        if (pat == "cas" || size != "16") {
+          source_set("lse_${pat}_${size}_${model}") {
+            # Assign to sources like this to hide from
+            # sync_source_lists_from_cmake.py which won't find the source file
+            # on the CMake side.
+            lse_file = "aarch64/lse.S"
+            sources = [ lse_file ]
+            include_dirs = [ "." ]
+            defines = [
+              "L_$pat",
+              "SIZE=$size",
+              "MODEL=$model",
+            ]
+          }
+          lse_targets += [ ":lse_${pat}_${size}_${model}" ]
+        }
+      }
+    }
+  }
+}
+
 static_library("builtins") {
   output_dir = crt_current_out_dir
   if (current_os == "mac") {
     output_name = "clang_rt.osx"
   } else if (current_os == "ios" && current_cpu == "arm64") {
     output_name = "clang_rt.ios"
   } else if (current_os == "ios" && current_cpu == "x64") {
     output_name = "clang_rt.iossim"
sources += [
       "ve/grow_stack.S",
       "ve/grow_stack_align.S",
     ]
   }
 
   if (!compiler_rt_exclude_atomic_builtin) {
     sources += [ "atomic.c" ]
   }
+
+  deps = lse_targets
 }
 
 # Currently unused but necessary to make sync_source_lists_from_cmake.py happy.
 source_set("_unused") {
   sources = [
     # Thumb1
     "arm/addsf3.S",
     "arm/comparesf2.S",
     "arm/divsi3.S",
     "arm/udivsi3.S",
   ]
 }