[InstSimplify] Fold (ctpop(X) == N) || (X != 0) into X != 0 where N > 0

[hkmatsumoto]

Summary

(ctpop(X) == N) || (X != 0) --> (X != 0) https://alive2.llvm.org/ce/z/hYL5C2 (for N = 10)
(ctpop(X) != N) && (X == 0) --> (X == 0) https://alive2.llvm.org/ce/z/oLkMvI (for N = 15)

[hkmatsumoto]

Proof (This is first time writing proof in English, so sorry for any inconveniences)
Suppose X: i32

1. For 0 < N <= 32
   • ctpop(X) == N --> X > 0.
   • Hence (ctpop(X) == N) || (X != 0) --> X > 0 || X != 0.
   • Intuitively X > 0 || X != 0 --> X != 0.
2. For 32 < N (This case is already optimized anyway)
   • ctpop(X) == N is always false, because of the semantics of ctpop().
   • Hence (ctpop(X) == N) || (X != 0) --> false || X != 0 --> X != 0.

[spatel]

If we are not creating a new value in a transformation (only returning an existing value or constant), we usually prefer to add that fold (and tests) to "InstSimplify".

Note that you can use "llvm.assume" with Alive2 to create a more general proof instead of using a specific constant:
https://alive2.llvm.org/ce/z/vcY7_s

[hkmatsumoto]

• Move change and its test to InstSimplify

• Remove/unchange tests whose and/or are replaced with select

This is because InstSimlify/and-or-icmp-* tests do not include such tests, and as far as I tried on goldbot.org simplifyAndOrOfICmps* functions in InstructionSimplify.cpp does not acknowledge select operands to optimize.

[spatel]

llvm/lib/Analysis/InstructionSimplify.cpp

1811 ↗

(On Diff #419469)

Normally in this kind of code, we name this "C" (for constant).

1814 ↗

(On Diff #419469)

Use m_ZeroInt() instead of m_SpecificInt()?

1815 ↗

(On Diff #419469)

It seems more natural if we write this as "!C->isZero()"

llvm/test/Transforms/InstCombine/ispow2.ll

1218

We should add a new test for "wrong predicate" because this test and the later one are reduced before we reach the transform in InstCombine.

llvm/test/Transforms/InstSimplify/and-or-icmp-ctpop.ll

35 ↗

(On Diff #419469)

Should this be or <2 x i1> %cmp, %notzero?

[spatel]

I posted inline comments on this patch yesterday, but it did not appear to trigger an email.

[hkmatsumoto]

Oops, sorry I actually got the email but was hidden under a bunch of others.
Let me quickly address some of your reviews, and address all of them tomorrow morning.

[hkmatsumoto]

Address code reviews

[spatel]

In D122757#3422764, @hkmatsumoto wrote:

Oops, sorry I actually got the email but was hidden under a bunch of others.
Let me quickly address some of your reviews, and address all of them tomorrow morning.

Ah - I actually see the mail too now, but it was also buried in my inbox. :)

Thanks for the updates. I think you can request commit access now if you have not already:
https://llvm.org/docs/DeveloperPolicy.html#obtaining-commit-access

If you get that, you can add the new tests as an "NFC" patch first. After that, this patch should be good to commit too.

[hkmatsumoto]

Update negative tests

[hkmatsumoto]

I pre-committed tests but immediately reverted as I noticed I forgot to rerun update_test_checks.py to make them baseline tests.
Let me take some time to confirm that the revert commit (rGf65c78a0949023bb0f3051cdaea7758e48420978) made CI pass.

[hkmatsumoto]

Sync with main branch

[spatel]

LGTM

llvm/lib/Transforms/InstCombine/InstCombineAndOrXor.cpp

static Value *foldSignedTruncationCheck(ICmpInst *ICmp0, ICmpInst *ICmp1,
   }
   // Else, if it does not, then all is ok as-is.
 
   // %r = icmp ult %X, SignBit
   return Builder.CreateICmpULT(X, ConstantInt::get(X->getType(), HighestBit),
                                CxtI.getName() + ".simplified");
 }
 
+/// Fold:
+/// (ctpop(X) == N) || (X != 0) --> X != 0
+/// (ctpop(X) != N) && (X == 0) --> X == 0
+/// where N > 0
+static Value *foldAndOrOfICmpsWithCtpop(ICmpInst *Cmp0, ICmpInst *Cmp1,
+                                        bool IsAnd,
+                                        InstCombiner::BuilderTy &Builder) {
+  CmpInst::Predicate Pred0, Pred1;
+  Value *X;
+  const APInt *N;
+  if (!match(Cmp0, m_ICmp(Pred0, m_Intrinsic<Intrinsic::ctpop>(m_Value(X)),
+                          m_APInt(N))) ||
+      !match(Cmp1, m_ICmp(Pred1, m_Specific(X), m_SpecificInt(0))) ||
+      !N->ugt(0))
+    return nullptr;
+
+  // (ctpop(X) == N) || (X != 0) --> X != 0 where N > 0
+  if (!IsAnd && Pred0 == ICmpInst::ICMP_EQ && Pred1 == ICmpInst::ICMP_NE)
+    return Builder.CreateICmpNE(X, ConstantInt::getNullValue(X->getType()));
+  // (ctpop(X) != N) && (X == 0) --> X == 0 where N > 0
+  if (IsAnd && Pred0 == ICmpInst::ICMP_NE && Pred1 == ICmpInst::ICMP_EQ)
+    return Builder.CreateICmpEQ(X, ConstantInt::getNullValue(X->getType()));
+
+  return nullptr;
+}
+
 /// Fold (icmp eq ctpop(X) 1) | (icmp eq X 0) into (icmp ult ctpop(X) 2) and
 /// fold (icmp ne ctpop(X) 1) & (icmp ne X 0) into (icmp ugt ctpop(X) 1).
 static Value *foldIsPowerOf2OrZero(ICmpInst *Cmp0, ICmpInst *Cmp1, bool IsAnd,
                                    InstCombiner::BuilderTy &Builder) {
   CmpInst::Predicate Pred0, Pred1;
   Value *X;
   if (!match(Cmp0, m_ICmp(Pred0, m_Intrinsic<Intrinsic::ctpop>(m_Value(X)),
                           m_SpecificInt(1))) ||
Value *InstCombinerImpl::foldAndOfICmps(ICmpInst *LHS, ICmpInst *RHS,
   if (Value *V = foldAndOrOfICmpsWithConstEq(RHS, LHS, And, Builder, Q))
     return V;
 
   if (Value *V = foldIsPowerOf2OrZero(LHS, RHS, /*IsAnd=*/true, Builder))
     return V;
   if (Value *V = foldIsPowerOf2OrZero(RHS, LHS, /*IsAnd=*/true, Builder))
     return V;
 
+  if (Value *V = foldAndOrOfICmpsWithCtpop(LHS, RHS, /*IsAnd=*/true, Builder))
+    return V;
+  if (Value *V = foldAndOrOfICmpsWithCtpop(RHS, LHS, /*IsAnd=*/true, Builder))
+    return V;
+
   // E.g. (icmp sge x, 0) & (icmp slt x, n) --> icmp ult x, n
   if (Value *V = simplifyRangeCheck(LHS, RHS, /*Inverted=*/false))
     return V;
 
   // E.g. (icmp slt x, n) & (icmp sge x, 0) --> icmp ult x, n
   if (Value *V = simplifyRangeCheck(RHS, LHS, /*Inverted=*/false))
     return V;
 
Value *InstCombinerImpl::foldOrOfICmps(ICmpInst *LHS, ICmpInst *RHS,
   if (Value *V = foldAndOrOfICmpsWithConstEq(RHS, LHS, Or, Builder, Q))
     return V;
 
   if (Value *V = foldIsPowerOf2OrZero(LHS, RHS, /*IsAnd=*/false, Builder))
     return V;
   if (Value *V = foldIsPowerOf2OrZero(RHS, LHS, /*IsAnd=*/false, Builder))
     return V;
 
+  if (Value *V = foldAndOrOfICmpsWithCtpop(LHS, RHS, /*IsAnd=*/false, Builder))
+    return V;
+  if (Value *V = foldAndOrOfICmpsWithCtpop(RHS, LHS, /*IsAnd=*/false, Builder))
+    return V;
+
   // E.g. (icmp slt x, 0) | (icmp sgt x, n) --> icmp ugt x, n
   if (Value *V = simplifyRangeCheck(LHS, RHS, /*Inverted=*/true))
     return V;
 
   // E.g. (icmp sgt x, n) | (icmp slt x, 0) --> icmp ugt x, n
   if (Value *V = simplifyRangeCheck(RHS, LHS, /*Inverted=*/true))
     return V;
 

llvm/test/Transforms/InstCombine/ispow2.ll

;
   %dec = add <2 x i8> %x, <i8 -1, i8 -1>
   %and = and <2 x i8> %dec, %x
   %cmp = icmp ne <2 x i8> %and, zeroinitializer
   %iszero = icmp eq <2 x i8> %x, zeroinitializer
   %r = or <2 x i1> %cmp, %iszero
   ret <2 x i1> %r
 }
 
+; (ctpop(X) == N) || (X != 0) --> X != 0
+; where N > 0
+
+define i1 @is_pow2ornon0_ctpop(i32 %x) {
+; CHECK-LABEL: @is_pow2ornon0_ctpop(
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp ne i32 [[X:%.*]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  %cmp = icmp eq i32 %t0, 10
+  %notzero = icmp ne i32 %x, 0
+  %r = or i1 %notzero, %cmp
+  ret i1 %r
+}
+
+define i1 @is_pow2ornon0_ctpop_swap_cmp(i32 %x) {
+; CHECK-LABEL: @is_pow2ornon0_ctpop_swap_cmp(
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp ne i32 [[X:%.*]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  %cmp = icmp eq i32 %t0, 20
+  %notzero = icmp ne i32 %x, 0
+  %r = or i1 %cmp, %notzero
+  ret i1 %r
+}
+
+define i1 @is_pow2ornon0_ctpop_logical(i32 %x) {
+; CHECK-LABEL: @is_pow2ornon0_ctpop_logical(
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp ne i32 [[X:%.*]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  %cmp = icmp eq i32 %t0, 30
+  %notzero = icmp ne i32 %x, 0
+  %r = select i1 %notzero, i1 true, i1 %cmp
+  ret i1 %r
+}
+
+define <2 x i1> @is_pow2ornon0_ctpop_commute_vec(<2 x i8> %x) {
+; CHECK-LABEL: @is_pow2ornon0_ctpop_commute_vec(
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp ne <2 x i8> [[X:%.*]], zeroinitializer
+; CHECK-NEXT:    ret <2 x i1> [[TMP1]]
+;
+  %t0 = tail call <2 x i8> @llvm.ctpop.v2i8(<2 x i8> %x)
+  %cmp = icmp eq <2 x i8> %t0, <i8 3, i8 3>
+  %iszero = icmp ne <2 x i8> %x, <i8 0, i8 0>
+  %r = or <2 x i1> %iszero, %cmp
+  ret <2 x i1> %r
+}
+
+; Extra uses don't change the fold.
+
+define i1 @is_pow2ornon0_ctpop_extra_uses(i32 %x) {
+; CHECK-LABEL: @is_pow2ornon0_ctpop_extra_uses(
+; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
+; CHECK-NEXT:    call void @use(i32 [[T0]])
+; CHECK-NEXT:    [[CMP:%.*]] = icmp eq i32 [[T0]], 1
+; CHECK-NEXT:    call void @use_i1(i1 [[CMP]])
+; CHECK-NEXT:    [[NOTZERO:%.*]] = icmp ne i32 [[X]], 0
+; CHECK-NEXT:    call void @use_i1(i1 [[NOTZERO]])
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp ne i32 [[X]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  call void @use(i32 %t0)
+  %cmp = icmp eq i32 %t0, 1
+  call void @use_i1(i1 %cmp)
+  %notzero = icmp ne i32 %x, 0
+  call void @use_i1(i1 %notzero)
+  %r = or i1 %notzero, %cmp
+  ret i1 %r
+}
+
+define i1 @is_pow2ornon0_ctpop_logical_extra_uses(i32 %x) {
+; CHECK-LABEL: @is_pow2ornon0_ctpop_logical_extra_uses(
+; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
+; CHECK-NEXT:    call void @use(i32 [[T0]])
+; CHECK-NEXT:    [[CMP:%.*]] = icmp eq i32 [[T0]], 1
+; CHECK-NEXT:    call void @use_i1(i1 [[CMP]])
+; CHECK-NEXT:    [[NOTZERO:%.*]] = icmp ne i32 [[X]], 0
+; CHECK-NEXT:    call void @use_i1(i1 [[NOTZERO]])
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp ne i32 [[X]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  call void @use(i32 %t0)
+  %cmp = icmp eq i32 %t0, 1
+  call void @use_i1(i1 %cmp)
+  %notzero = icmp ne i32 %x, 0
+  call void @use_i1(i1 %notzero)
+  %r = select i1 %notzero, i1 true, i1 %cmp
+  ret i1 %r
+}
+
+; Negative test - wrong constant.
+
+define <2 x i1> @is_pow2ornon0_ctpop_commute_vec_wrong_cmp_op1(<2 x i8> %x) {
+; CHECK-LABEL: @is_pow2ornon0_ctpop_commute_vec_wrong_cmp_op1(
+; CHECK-NEXT:    [[T0:%.*]] = tail call <2 x i8> @llvm.ctpop.v2i8(<2 x i8> [[X:%.*]])
+; CHECK-NEXT:    [[CMP:%.*]] = icmp eq <2 x i8> [[T0]], <i8 -1, i8 1>
+; CHECK-NEXT:    [[ISZERO:%.*]] = icmp ne <2 x i8> [[X]], zeroinitializer
+; CHECK-NEXT:    [[R:%.*]] = or <2 x i1> [[ISZERO]], [[CMP]]
+; CHECK-NEXT:    ret <2 x i1> [[R]]
+;
+  %t0 = tail call <2 x i8> @llvm.ctpop.v2i8(<2 x i8> %x)
+  %cmp = icmp eq <2 x i8> %t0, <i8 -1, i8 1>
+  %iszero = icmp ne <2 x i8> %x, <i8 0, i8 0>
+  %r = or <2 x i1> %iszero, %cmp
+  ret <2 x i1> %r
+}
+
+; Negative test - wrong predicate.
+
+define i1 @is_pow2ornon0_ctpop_wrong_pred1(i32 %x) {
+; CHECK-LABEL: @is_pow2ornon0_ctpop_wrong_pred1(
+; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
+; CHECK-NEXT:    [[CMP:%.*]] = icmp ne i32 [[T0]], 1
+; CHECK-NEXT:    [[NOTZERO:%.*]] = icmp ne i32 [[X]], 0
+; CHECK-NEXT:    [[R:%.*]] = or i1 [[NOTZERO]], [[CMP]]
+; CHECK-NEXT:    ret i1 [[R]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  %cmp = icmp ne i32 %t0, 1
+  %notzero = icmp ne i32 %x, 0
+  %r = or i1 %notzero, %cmp
+  ret i1 %r
+}
+
+define i1 @is_pow2ornon0_ctpop_wrong_pred2_logical(i32 %x) {
+; CHECK-LABEL: @is_pow2ornon0_ctpop_wrong_pred2_logical(
+; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
+; CHECK-NEXT:    [[CMP:%.*]] = icmp ne i32 [[T0]], 2
+; CHECK-NEXT:    [[NOTZERO:%.*]] = icmp eq i32 [[X]], 0
+; CHECK-NEXT:    [[R:%.*]] = or i1 [[NOTZERO]], [[CMP]]
+; CHECK-NEXT:    ret i1 [[R]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  %cmp = icmp ne i32 %t0, 2
+  %notzero = icmp eq i32 %x, 0
+  %r = select i1 %notzero, i1 true, i1 %cmp
+  ret i1 %r
+}
+
+define <2 x i1> @is_pow2ornon0_ctpop_commute_vec_wrong_pred3(<2 x i8> %x) {
+; CHECK-LABEL: @is_pow2ornon0_ctpop_commute_vec_wrong_pred3(
+; CHECK-NEXT:    [[T0:%.*]] = tail call <2 x i8> @llvm.ctpop.v2i8(<2 x i8> [[X:%.*]])
+; CHECK-NEXT:    [[CMP:%.*]] = icmp eq <2 x i8> [[T0]], <i8 1, i8 1>
+; CHECK-NEXT:    [[ISZERO:%.*]] = icmp ne <2 x i8> [[X]], zeroinitializer
+; CHECK-NEXT:    [[R:%.*]] = and <2 x i1> [[ISZERO]], [[CMP]]
+; CHECK-NEXT:    ret <2 x i1> [[R]]
+;
+  %t0 = tail call <2 x i8> @llvm.ctpop.v2i8(<2 x i8> %x)
+  %cmp = icmp eq <2 x i8> %t0, <i8 1, i8 1>
+  %iszero = icmp ne <2 x i8> %x, <i8 0, i8 0>
+  %r = and <2 x i1> %iszero, %cmp
+  ret <2 x i1> %r
+}
+
+; (ctpop(X) != N) && (X == 0) --> X == 0
+; where N > 0
+
+define i1 @isnot_pow2but0_ctpop(i32 %x) {
+; CHECK-LABEL: @isnot_pow2but0_ctpop(
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp eq i32 [[X:%.*]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  %cmp = icmp ne i32 %t0, 1
+  %iszero = icmp eq i32 %x, 0
+  %r = and i1 %iszero, %cmp
+  ret i1 %r
+}
+
+define i1 @isnot_pow2but0_ctpop_swap_cmp(i32 %x) {
+; CHECK-LABEL: @isnot_pow2but0_ctpop_swap_cmp(
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp eq i32 [[X:%.*]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  %cmp = icmp ne i32 %t0, 1
+  %iszero = icmp eq i32 %x, 0
+  %r = and i1 %cmp, %iszero
+  ret i1 %r
+}
+
+define i1 @isnot_pow2but0_ctpop_logical(i32 %x) {
+; CHECK-LABEL: @isnot_pow2but0_ctpop_logical(
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp eq i32 [[X:%.*]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  %cmp = icmp ne i32 %t0, 1
+  %iszero = icmp eq i32 %x, 0
+  %r = select i1 %iszero, i1 %cmp, i1 false
+  ret i1 %r
+}
+
+define <2 x i1> @isnot_pow2but0_ctpop_commute_vec(<2 x i8> %x) {
+; CHECK-LABEL: @isnot_pow2but0_ctpop_commute_vec(
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp eq <2 x i8> [[X:%.*]], zeroinitializer
+; CHECK-NEXT:    ret <2 x i1> [[TMP1]]
+;
+  %t0 = tail call <2 x i8> @llvm.ctpop.v2i8(<2 x i8> %x)
+  %cmp = icmp ne <2 x i8> %t0, <i8 1, i8 1>
+  %iszero = icmp eq <2 x i8> %x, <i8 0, i8 0>
+  %r = and <2 x i1> %iszero, %cmp
+  ret <2 x i1> %r
+}
+
+; Extra uses don't change the fold.
+
+define i1 @isnot_pow2but0_ctpop_extra_uses(i32 %x) {
+; CHECK-LABEL: @isnot_pow2but0_ctpop_extra_uses(
+; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
+; CHECK-NEXT:    call void @use(i32 [[T0]])
+; CHECK-NEXT:    [[CMP:%.*]] = icmp ne i32 [[T0]], 1
+; CHECK-NEXT:    call void @use_i1(i1 [[CMP]])
+; CHECK-NEXT:    [[ISZERO:%.*]] = icmp eq i32 [[X]], 0
+; CHECK-NEXT:    call void @use_i1(i1 [[ISZERO]])
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp eq i32 [[X]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  call void @use(i32 %t0)
+  %cmp = icmp ne i32 %t0, 1
+  call void @use_i1(i1 %cmp)
+  %iszero = icmp eq i32 %x, 0
+  call void @use_i1(i1 %iszero)
+  %r = and i1 %iszero, %cmp
+  ret i1 %r
+}
+
+define i1 @isnot_pow2but0_ctpop_logical_extra_uses(i32 %x) {
+; CHECK-LABEL: @isnot_pow2but0_ctpop_logical_extra_uses(
+; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
+; CHECK-NEXT:    call void @use(i32 [[T0]])
+; CHECK-NEXT:    [[CMP:%.*]] = icmp ne i32 [[T0]], 1
+; CHECK-NEXT:    call void @use_i1(i1 [[CMP]])
+; CHECK-NEXT:    [[ISZERO:%.*]] = icmp eq i32 [[X]], 0
+; CHECK-NEXT:    call void @use_i1(i1 [[ISZERO]])
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp eq i32 [[X]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  call void @use(i32 %t0)
+  %cmp = icmp ne i32 %t0, 1
+  call void @use_i1(i1 %cmp)
+  %iszero = icmp eq i32 %x, 0
+  call void @use_i1(i1 %iszero)
+  %r = select i1 %iszero, i1 %cmp, i1 false
+  ret i1 %r
+}
+
+; Negative test - wrong constant.
+
+define <2 x i1> @isnot_pow2but0_ctpop_commute_vec_wrong_cmp_op1(<2 x i8> %x) {
+; CHECK-LABEL: @isnot_pow2but0_ctpop_commute_vec_wrong_cmp_op1(
+; CHECK-NEXT:    [[T0:%.*]] = tail call <2 x i8> @llvm.ctpop.v2i8(<2 x i8> [[X:%.*]])
+; CHECK-NEXT:    [[CMP:%.*]] = icmp ne <2 x i8> [[T0]], <i8 -1, i8 1>
+; CHECK-NEXT:    [[ISZERO:%.*]] = icmp eq <2 x i8> [[X]], zeroinitializer
+; CHECK-NEXT:    [[R:%.*]] = and <2 x i1> [[ISZERO]], [[CMP]]
+; CHECK-NEXT:    ret <2 x i1> [[R]]
+;
+  %t0 = tail call <2 x i8> @llvm.ctpop.v2i8(<2 x i8> %x)
+  %cmp = icmp ne <2 x i8> %t0, <i8 -1, i8 1>
+  %iszero = icmp eq <2 x i8> %x, <i8 0, i8 0>
+  %r = and <2 x i1> %iszero, %cmp
+  ret <2 x i1> %r
+}
+
+; Negative test - wrong predicate.
+
+define i1 @isnot_pow2but0_ctpop_wrong_pred1(i32 %x) {
+; CHECK-LABEL: @isnot_pow2but0_ctpop_wrong_pred1(
+; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
+; CHECK-NEXT:    [[CMP:%.*]] = icmp eq i32 [[T0]], 1
+; CHECK-NEXT:    [[ISZERO:%.*]] = icmp eq i32 [[X]], 0
+; CHECK-NEXT:    [[R:%.*]] = and i1 [[ISZERO]], [[CMP]]
+; CHECK-NEXT:    ret i1 [[R]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  %cmp = icmp eq i32 %t0, 1
+  %iszero = icmp eq i32 %x, 0
+  %r = and i1 %iszero, %cmp
+  ret i1 %r
+}
+
+define i1 @isnot_pow2but0_ctpop_wrong_pred2_logical(i32 %x) {
+; CHECK-LABEL: @isnot_pow2but0_ctpop_wrong_pred2_logical(
+; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
+; CHECK-NEXT:    [[CMP:%.*]] = icmp eq i32 [[T0]], 1
+; CHECK-NEXT:    [[ISZERO:%.*]] = icmp ne i32 [[X]], 0
+; CHECK-NEXT:    [[R:%.*]] = and i1 [[ISZERO]], [[CMP]]
+; CHECK-NEXT:    ret i1 [[R]]
+;
+  %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
+  %cmp = icmp eq i32 %t0, 1
+  %iszero = icmp ne i32 %x, 0
+  %r = select i1 %iszero, i1 %cmp, i1 false
+  ret i1 %r
+}
+
+define <2 x i1> @isnot_pow2but0_ctpop_commute_vec_wrong_pred3(<2 x i8> %x) {
+; CHECK-LABEL: @isnot_pow2but0_ctpop_commute_vec_wrong_pred3(
+; CHECK-NEXT:    [[T0:%.*]] = tail call <2 x i8> @llvm.ctpop.v2i8(<2 x i8> [[X:%.*]])
+; CHECK-NEXT:    [[CMP:%.*]] = icmp ne <2 x i8> [[T0]], <i8 1, i8 1>
+; CHECK-NEXT:    [[ISZERO:%.*]] = icmp eq <2 x i8> [[X]], zeroinitializer
+; CHECK-NEXT:    [[R:%.*]] = or <2 x i1> [[ISZERO]], [[CMP]]
+; CHECK-NEXT:    ret <2 x i1> [[R]]
+;
+  %t0 = tail call <2 x i8> @llvm.ctpop.v2i8(<2 x i8> %x)
+  %cmp = icmp ne <2 x i8> %t0, <i8 1, i8 1>
+  %iszero = icmp eq <2 x i8> %x, <i8 0, i8 0>
+  %r = or <2 x i1> %iszero, %cmp
+  ret <2 x i1> %r
+}
+
 ; (ctpop(X) == 1) || (X == 0) --> ctpop(X) u< 2
 
 define i1 @is_pow2or0_ctpop(i32 %x) {
 ; CHECK-LABEL: @is_pow2or0_ctpop(
 ; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
 ; CHECK-NEXT:    [[TMP1:%.*]] = icmp ult i32 [[T0]], 2
 ; CHECK-NEXT:    ret i1 [[TMP1]]
 ;

 ;
   %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
   %cmp = icmp ne i32 %t0, 1
   %iszero = icmp eq i32 %x, 0
   %r = or i1 %iszero, %cmp
   ret i1 %r
 }
 
 define i1 @is_pow2or0_ctpop_wrong_pred2_logical(i32 %x) {
 ; CHECK-LABEL: @is_pow2or0_ctpop_wrong_pred2_logical(
-; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
-; CHECK-NEXT:    [[CMP:%.*]] = icmp eq i32 [[T0]], 1
-; CHECK-NEXT:    [[ISZERO:%.*]] = icmp ne i32 [[X]], 0
-; CHECK-NEXT:    [[R:%.*]] = or i1 [[ISZERO]], [[CMP]]
-; CHECK-NEXT:    ret i1 [[R]]
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp ne i32 [[X:%.*]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
 ;
   %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
   %cmp = icmp eq i32 %t0, 1
   %iszero = icmp ne i32 %x, 0
   %r = select i1 %iszero, i1 true, i1 %cmp
   ret i1 %r
 }
 
;
   %cmp = icmp eq i32 %t0, 1
   %notzero = icmp ne i32 %x, 0
   %r = and i1 %notzero, %cmp
   ret i1 %r
 }
 
 define i1 @isnot_pow2nor0_ctpop_wrong_pred2_logical(i32 %x) {
 ; CHECK-LABEL: @isnot_pow2nor0_ctpop_wrong_pred2_logical(
-; CHECK-NEXT:    [[T0:%.*]] = tail call i32 @llvm.ctpop.i32(i32 [[X:%.*]]), !range [[RNG0]]
-; CHECK-NEXT:    [[CMP:%.*]] = icmp ne i32 [[T0]], 1
-; CHECK-NEXT:    [[NOTZERO:%.*]] = icmp eq i32 [[X]], 0
-; CHECK-NEXT:    [[R:%.*]] = and i1 [[NOTZERO]], [[CMP]]
-; CHECK-NEXT:    ret i1 [[R]]
+; CHECK-NEXT:    [[TMP1:%.*]] = icmp eq i32 [[X:%.*]], 0
+; CHECK-NEXT:    ret i1 [[TMP1]]
 ;
   %t0 = tail call i32 @llvm.ctpop.i32(i32 %x)
   %cmp = icmp ne i32 %t0, 1
   %notzero = icmp eq i32 %x, 0
   %r = select i1 %notzero, i1 %cmp, i1 false
   ret i1 %r
 }