[gn build] Make build locally deterministic

[thakis]

Summary

This follows http://blog.llvm.org/2019/11/deterministic-builds-with-clang-and-lld.html
to make the GN build locally deterministic.

With this, I've built lld at two different build paths on my Windows box and got
identical binaries. (I'd expect the same to happen on Linux, and with other
binaries.)

This doesn't have the bits to get universal determinism yet.

[rnk]

lgtm

llvm/utils/gn/build/BUILD.gn

 import("//llvm/utils/gn/build/buildflags.gni")
 import("//llvm/utils/gn/build/mac_sdk.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 import("//llvm/utils/gn/build/toolchain/target_flags.gni")
 
 declare_args() {
   # Whether to build everything with coverage information.
   # After building with this, run tests and then run
   #    llvm/utils/prepare-code-coverage-artifact.py  \
   #        .../llvm-profdata .../llvm-cov out/gn/profiles/ report/ \
   #        out/gn/bin/llvm-undname ...`
   # to generate a HTML report for the binaries passed in the last line.
   llvm_build_instrumented_coverage = false
+
+  # If set, puts relative paths in debug info.
+  # Makes the build output independent of the build directory, but makes
+  # most debuggers harder to use. See "Getting to local determinism" and
+  # "Getting debuggers to work well with locally deterministic builds" in
+  # http://blog.llvm.org/2019/11/deterministic-builds-with-clang-and-lld.html
+  # for more information.
+  use_relative_paths_in_debug_info = false
 }
 
 assert(!llvm_build_instrumented_coverage || is_clang,
        "llvm_build_instrumented_coverage requires clang as host compiler")
 
 config("compiler_defaults") {
   defines = []
 
cflags += [
       # for test execution -- so this is the only way to get all profiles into
       # a single folder like llvm/utils/prepare-code-coverage-artifact.py
       # expects.
       "-fprofile-instr-generate=" +
           rebase_path("$root_build_dir/profiles/%4m.profraw"),
     ]
     ldflags += [ "-fprofile-instr-generate" ]
   }
+
+  # Deterministic build setup, see
+  # http://blog.llvm.org/2019/11/deterministic-builds-with-clang-and-lld.html
+  if (current_os == "win") {
+    ldflags += [ "/pdbaltpath:%_PDB%" ]
+  }
+  if (is_clang) {
+    cflags += [
+      "-no-canonical-prefixes",
+      "-Werror=date-time",
+    ]
+    if (current_os == "win") {
+      cflags += [
+        "-fmsc-version=1916",
+        "/X",
+      ]
+    }
+    if (current_os == "win" && use_lld) {
+      cflags += [ "/Brepro" ]
+      ldflags += [
+        "/Brepro",
+        "/lldignoreenv",
+      ]
+    }
+    if (use_relative_paths_in_debug_info) {
+      cflags += [
+        "-fdebug-compilation-dir",
+        ".",
+      ]
+    }
+  }
 }
 
 config("no_exceptions") {
   if (host_os != "win") {
     cflags_cc = [ "-fno-exceptions" ]
   }
 }
 

llvm/utils/gn/build/toolchain/BUILD.gn

tool("asm") {
       command = "$cc -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{asmflags}}"
       depsformat = "gcc"
       description = "ASM {{output}}"
       outputs = [ "{{source_out_dir}}/{{label_name}}.{{source_name_part}}.o" ]
     }
 
     tool("alink") {
       if (current_os == "mac") {
-        command = "libtool -static -no_warning_for_no_symbols {{arflags}} -o {{output}} {{inputs}}"
+        command = "libtool -D -static -no_warning_for_no_symbols {{arflags}} -o {{output}} {{inputs}}"
       } else {
         # Remove the output file first so that ar doesn't try to modify the
         # existing file.
         command =
             "rm -f {{output}} && $ar rcsD {{arflags}} {{output}} {{inputs}}"
       }
       description = "AR {{output}}"
       outputs = [ "{{output_dir}}/{{target_output_name}}.a" ]

llvm/utils/gn/docs/deterministic.md

+Deterministic builds with LLVM's GN build
+=========================================
+
+Summary: Use the following args.gn.
+
+    use_relative_paths_in_debug_info = true
+
+It is possible to produce [locally deterministic][1] builds of LLVM
+with the GN build. It requires some configuration though.
+
+1. Make debug info use relative paths by setting
+   `use_relative_paths_in_debug_info = true` in your `args.gn` file. With this
+   set, current debuggers need minor configuration to keep working.  See
+   "Getting to local determinism" and "Getting debuggers to work well with
+   locally deterministic builds" in the [deterministic builds][1] documentation
+   for details.
+
+1: http://blog.llvm.org/2019/11/deterministic-builds-with-clang-and-lld.html