gn build: Add NVPTX target

[thakis]

Summary

The NVPTX target is a bit unusual in that it's the only target without a disassembler, and one of three targets without an asm parser (and the first one of those three in the gn build). NVPTX doesn't have those because it's not a binary format.

The CMake build checks for the existence of {AsmParser,Disassembler}/CMakeLists.txt when setting LLVM_ENUM_ASM_PARSERS / LLVM_ENUM_DISASSEBLERS (http://llvm-cs.pcc.me.uk/CMakeLists.txt#744). The GN build doesn't want to hit the disk for things like this, so instead I'm adding explicit targets_with_asm_parsers and targets_with_disassemblers lists. Since both are needed rarely, they are defined in their own gni files.

[tra]

Yay! Thank you. Lack of this has stopped me when I tried gn last time. I'll try again once this patch lands.

[phosek]

Since you always include all three of //llvm/lib/Target/targets.gni, //llvm/lib/Target/targets_with_asm_parsers.gni, //llvm/lib/Target/targets_with_disassemblers.gni, why not just combine all of them into //llvm/lib/Target/targets.gni? If we ever need them separately and performance becomes an issue, we can split them later.

LGTM otherwise.

[thakis]

Thanks! Most includes of targets.gni don't need the two new files: http://llvm-cs.pcc.me.uk/?q=targets.gni

I could combine the two files into one, but I couldn't think of a good name :P

llvm/trunk/utils/gn/TODO.txt

 Ideas for things to do:
 
 - more projects (compiler-rt's asan/ubsan/msan/tsan, lldb)
   - once there are more projects, have an llvm_enable_projects arg, modeled
     after llvm_targets_to_build in the GN build
   - a check-all build target that runs test of all projects
-- more targets (AMDGPU ARC AVR MSP430 NVPTX XCore)
+- more targets (AMDGPU ARC AVR MSP430 XCore)
   - example: https://reviews.llvm.org/D56416
 - investigate feasibility of working `gn check`
 
 - "optimized tblgen" mode
   - either just always build tablegen and support with opt config
   - or use opt toolchain and build tablegen twice in debug builds, like cmake
 
 - cross builds using GN's toolchain feature

llvm/trunk/utils/gn/secondary/llvm/include/llvm/Config/BUILD.gn

 import("//llvm/lib/DebugInfo/PDB/enable_dia.gni")
 import("//llvm/lib/Target/targets.gni")
+import("//llvm/lib/Target/targets_with_asm_parsers.gni")
+import("//llvm/lib/Target/targets_with_disassemblers.gni")
 import("//llvm/triples.gni")
 import("//llvm/utils/gn/build/buildflags.gni")
 import("//llvm/utils/gn/build/libs/edit/enable.gni")
 import("//llvm/utils/gn/build/libs/pthread/enable.gni")
 import("//llvm/utils/gn/build/libs/terminfo/enable.gni")
 import("//llvm/utils/gn/build/libs/xar/enable.gni")
 import("//llvm/utils/gn/build/libs/xml/enable.gni")
 import("//llvm/utils/gn/build/libs/zlib/enable.gni")
template("write_target_def_file") {
   assert(defined(invoker.key), "must set 'key' in $target_name")
   assert(defined(invoker.value), "must set 'value' in $target_name")
 
   write_cmake_config(target_name) {
     visibility = [ ":write_target_def_files" ]
     input = "$target_name.in"
     output = "$target_gen_dir/$target_name"
 
+    if (defined(invoker.all_targets)) {
+      all_targets = invoker.all_targets
+    } else {
+      all_targets = llvm_targets_to_build
+    }
+
     # Build something like
     # `LLVM_ENUM_ASM_PARSERS=LLVM_ASM_PARSER(ARM)\nLLVM_ASM_PARSER(X86)\n`. Note
     # that \n is a literal '\' followed by a literal 'n', not a newline
     # character.  (write_cmake_config.py replaces that with a real newline).
     value = ""
-    foreach(target, llvm_targets_to_build) {
+    foreach(target, all_targets) {
       value = "$value${invoker.value}($target)\n"
     }
     values = [ "${invoker.key}=$value" ]
   }
 }
 
 write_target_def_file("AsmParsers.def") {
   key = "LLVM_ENUM_ASM_PARSERS"
   value = "LLVM_ASM_PARSER"
+  all_targets = targets_with_asm_parsers
 }
 
 write_target_def_file("AsmPrinters.def") {
   key = "LLVM_ENUM_ASM_PRINTERS"
   value = "LLVM_ASM_PRINTER"
 }
 
 write_target_def_file("Disassemblers.def") {
   key = "LLVM_ENUM_DISASSEMBLERS"
   value = "LLVM_DISASSEMBLER"
+  all_targets = targets_with_disassemblers
 }
 
 write_target_def_file("Targets.def") {
   key = "LLVM_ENUM_TARGETS"
   value = "LLVM_TARGET"
 }
 
 group("write_target_def_files") {

llvm/trunk/utils/gn/secondary/llvm/lib/Target/BUILD.gn

 import("//llvm/lib/Target/targets.gni")
+import("//llvm/lib/Target/targets_with_asm_parsers.gni")
+import("//llvm/lib/Target/targets_with_disassemblers.gni")
 
 # This build file has two parts:
 # 1. The actual //llvm/lib/Target build target, which is just a static
 #    library containing the cpp files in this directory.  It contains general
 #    shared target code.
 # 2. Forwarding targets that forward to the concrete targets (X86, ARM, ...).
 #    These are defined in subdirectories, and the forwarding names match
 #    the names of the forwarding targets in CMake.  They all (indirectly,

 }
 
 group("TargetsToBuild") {
   deps = llvm_targets_to_build
 }
 
 group("AllTargetsAsmParsers") {
   deps = []
-  foreach(target, llvm_targets_to_build) {
+  foreach(target, targets_with_asm_parsers) {
     deps += [ "$target/AsmParser" ]
   }
 }
 
 group("AllTargetsDescs") {
   deps = []
   foreach(target, llvm_targets_to_build) {
     deps += [ "$target/MCTargetDesc" ]
   }
 }
 
 group("AllTargetsDisassemblers") {
   deps = []
-  foreach(target, llvm_targets_to_build) {
+  foreach(target, targets_with_disassemblers) {
     deps += [ "$target/Disassembler" ]
   }
 }
 
 group("AllTargetsInfos") {
   deps = []
   foreach(target, llvm_targets_to_build) {
     deps += [ "$target/TargetInfo" ]
   }
 }

llvm/trunk/utils/gn/secondary/llvm/lib/Target/NVPTX/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("NVPTXGenDAGISel") {
+  visibility = [ ":LLVMNVPTXCodeGen" ]
+  args = [ "-gen-dag-isel" ]
+  td_file = "NVPTX.td"
+}
+
+static_library("LLVMNVPTXCodeGen") {
+  deps = [
+    ":NVPTXGenDAGISel",
+    "MCTargetDesc",
+    "TargetInfo",
+    "//llvm/include/llvm/Config:llvm-config",
+    "//llvm/lib/Analysis",
+    "//llvm/lib/CodeGen",
+    "//llvm/lib/CodeGen/AsmPrinter",
+    "//llvm/lib/CodeGen/SelectionDAG",
+    "//llvm/lib/IR",
+    "//llvm/lib/MC",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target",
+    "//llvm/lib/Transforms/IPO",
+    "//llvm/lib/Transforms/Scalar",
+    "//llvm/lib/Transforms/Utils",
+    "//llvm/lib/Transforms/Vectorize",
+  ]
+  include_dirs = [ "." ]
+  sources = [
+    "NVPTXAllocaHoisting.cpp",
+    "NVPTXAsmPrinter.cpp",
+    "NVPTXAssignValidGlobalNames.cpp",
+    "NVPTXFrameLowering.cpp",
+    "NVPTXGenericToNVVM.cpp",
+    "NVPTXISelDAGToDAG.cpp",
+    "NVPTXISelLowering.cpp",
+    "NVPTXImageOptimizer.cpp",
+    "NVPTXInstrInfo.cpp",
+    "NVPTXLowerAggrCopies.cpp",
+    "NVPTXLowerAlloca.cpp",
+    "NVPTXLowerArgs.cpp",
+    "NVPTXMCExpr.cpp",
+    "NVPTXPeephole.cpp",
+    "NVPTXPrologEpilogPass.cpp",
+    "NVPTXProxyRegErasure.cpp",
+    "NVPTXRegisterInfo.cpp",
+    "NVPTXReplaceImageHandles.cpp",
+    "NVPTXSubtarget.cpp",
+    "NVPTXTargetMachine.cpp",
+    "NVPTXTargetTransformInfo.cpp",
+    "NVPTXUtilities.cpp",
+    "NVVMIntrRange.cpp",
+    "NVVMReflect.cpp",
+  ]
+}
+
+# This is a bit different from most build files: Due to this group
+# having the directory's name, "//llvm/lib/Target/NVPTX" will refer to this
+# target, which pulls in the code in this directory *and all subdirectories*.
+# For most other directories, "//llvm/lib/Foo" only pulls in the code directly
+# in "llvm/lib/Foo". The forwarding targets in //llvm/lib/Target expect this
+# different behavior.
+group("NVPTX") {
+  deps = [
+    ":LLVMNVPTXCodeGen",
+    "MCTargetDesc",
+    "TargetInfo",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/lib/Target/NVPTX/MCTargetDesc/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("NVPTXGenAsmWriter") {
+  visibility = [ ":MCTargetDesc" ]
+  args = [ "-gen-asm-writer" ]
+  td_file = "../NVPTX.td"
+}
+
+tablegen("NVPTXGenInstrInfo") {
+  visibility = [ ":MCTargetDesc" ]
+  args = [ "-gen-instr-info" ]
+  td_file = "../NVPTX.td"
+}
+
+tablegen("NVPTXGenRegisterInfo") {
+  visibility = [ ":MCTargetDesc" ]
+  args = [ "-gen-register-info" ]
+  td_file = "../NVPTX.td"
+}
+
+tablegen("NVPTXGenSubtargetInfo") {
+  visibility = [ ":MCTargetDesc" ]
+  args = [ "-gen-subtarget" ]
+  td_file = "../NVPTX.td"
+}
+
+static_library("MCTargetDesc") {
+  output_name = "LLVMNVPTXDesc"
+
+  # This should contain tablegen targets generating .inc files included
+  # by other targets. .inc files only used by .cpp files in this directory
+  # should be in deps on the static_library instead.
+  public_deps = [
+    ":NVPTXGenInstrInfo",
+    ":NVPTXGenRegisterInfo",
+    ":NVPTXGenSubtargetInfo",
+  ]
+  deps = [
+    ":NVPTXGenAsmWriter",
+    "//llvm/lib/MC",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target/NVPTX/TargetInfo",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "NVPTXInstPrinter.cpp",
+    "NVPTXMCAsmInfo.cpp",
+    "NVPTXMCTargetDesc.cpp",
+    "NVPTXTargetStreamer.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/lib/Target/NVPTX/TargetInfo/BUILD.gn

+static_library("TargetInfo") {
+  output_name = "LLVMNVPTXInfo"
+  deps = [
+    "//llvm/lib/Support",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "NVPTXTargetInfo.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/lib/Target/targets.gni

if (llvm_targets_to_build == "host") {
   # FIXME: Port the remaining targets.
   llvm_targets_to_build = [
     "AArch64",
     "ARM",
     "BPF",
     "Hexagon",
     "Lanai",
     "Mips",
+    "NVPTX",
     "PowerPC",
     "Sparc",
     "SystemZ",
     "WebAssembly",
     "X86",
   ]
 }
 
foreach(target, llvm_targets_to_build) {
   } else if (target == "BPF") {
     llvm_build_BPF = true
   } else if (target == "Hexagon") {
     # Nothing to do.
   } else if (target == "Lanai") {
     # Nothing to do.
   } else if (target == "Mips") {
     # Nothing to do.
+  } else if (target == "NVPTX") {
+    # Nothing to do.
   } else if (target == "PowerPC") {
     llvm_build_PowerPC = true
   } else if (target == "RISCV") {
     # Nothing to do.
   } else if (target == "Sparc") {
     # Nothing to do.
   } else if (target == "SystemZ") {
     # Nothing to do.

llvm/trunk/utils/gn/secondary/llvm/lib/Target/targets_with_asm_parsers.gni

+import("//llvm/lib/Target/targets.gni")
+
+targets_with_asm_parsers = []
+foreach(target, llvm_targets_to_build) {
+  # These targets don't have AsmParsers.
+  if (target != "ARC" && target != "NVPTX" && target != "XCore") {
+    targets_with_asm_parsers += [ target ]
+  }
+}

llvm/trunk/utils/gn/secondary/llvm/lib/Target/targets_with_disassemblers.gni

+import("//llvm/lib/Target/targets.gni")
+
+targets_with_disassemblers = []
+foreach(target, llvm_targets_to_build) {
+  # These targets don't have Disassemblers.
+  if (target != "NVPTX") {
+    targets_with_disassemblers += [ target ]
+  }
+}