[InstCombine] Add tests for add nuw + uaddo

[dlrobertson]

Summary

Baseline tests for D59471 (InstCombine of add nuw and uaddo with
constants).

[lebedev.ri]

llvm/test/Transforms/InstCombine/uadd-with-overflow.ll

3

Please run this test input through -instnamer first, and then strreplace tmp with t.
Else update script may get confused, or the output will be confusing to read.

https://godbolt.org/z/bX1_Os

[lebedev.ri]

llvm/test/Transforms/InstCombine/uadd-with-overflow.ll

87–96

Also add test with plain add.

[dlrobertson]

@lebedev.ri Both of your comments would also be valid for the tests for D58881. Should I update the tests there too?

llvm/test/Transforms/InstCombine/uadd-with-overflow.ll

3

Thanks! Good to know

87–96

Will do.

[lebedev.ri]

In D59472#1432509, @dlrobertson wrote:

@lebedev.ri Both of your comments would also be valid for the tests for D58881. Should I update the tests there too?

That would be nice i guess.

[dlrobertson]

• add test for a wrapped add
• don't use unnamed values in tests

[lebedev.ri]

LG

llvm/test/Transforms/InstCombine/uadd-with-overflow.ll

55

You could also add variations with non-splat non-undef constants

[dlrobertson]

llvm/test/Transforms/InstCombine/uadd-with-overflow.ll

55

I'm not sure I follow. Wouldn't a non-splat non-undef variation of this test be something like simple_fold on line 10?

[lebedev.ri]

llvm/test/Transforms/InstCombine/uadd-with-overflow.ll

55

I meant something like

%a = add nuw <2 x i32> %x, <i32 12, i32 13> ; not splat, but still no overflow, but won't get folded
%b = tail call { <2 x i32>, <2 x i1> } @llvm.uadd.with.overflow.v2i32(<2 x i32> %a, <2 x i32> <i32 30, i32 30>)

%a = add nuw <2 x i32> %x, <i32 12, i32 4294967280> ; not splat, overflow
%b = tail call { <2 x i32>, <2 x i1> } @llvm.uadd.with.overflow.v2i32(<2 x i32> %a, <2 x i32> <i32 30, i32 255>)

[nikic]

llvm/test/Transforms/InstCombine/uadd-with-overflow.ll

55

To clarify terminology: "Splat" here means that all elements of a vector constant are the same (or undef, in which case we may assume them to be the same). Non-splat is if the elements differ. For many optimizations only the splat case is supported, because it is handled by matchers like m_APInt(). Handling non-splat cases typically requires using ConstantExpr based operations (instead of much more convenient APInt ones), so mostly nobody bothers...

[lebedev.ri]

llvm/test/Transforms/InstCombine/uadd-with-overflow.ll

55

Right, i should have explained that. I didn't get that at first too.

[dlrobertson]

Added non-undef non-splat overflow and non-overflow tests

[dlrobertson]

llvm/test/Transforms/InstCombine/uadd-with-overflow.ll

55

Ah yeah I was confusing vector and splat. Thanks updated the patch.

llvm/test/Transforms/InstCombine/uadd-with-overflow.ll

+; NOTE: Assertions have been autogenerated by utils/update_test_checks.py
+; RUN: opt < %s -instcombine -S | FileCheck %s
+
+declare { <2 x i32>, <2 x i1> } @llvm.uadd.with.overflow.v2i32(<2 x i32>, <2 x i32>)
+
+declare { i32, i1 } @llvm.uadd.with.overflow.i32(i32, i32)
+
+declare { i8, i1 } @llvm.uadd.with.overflow.i8(i8, i8)
+
+define { i32, i1 } @simple_fold(i32) {
+; CHECK-LABEL: @simple_fold(
+; CHECK-NEXT:    [[TMP2:%.*]] = add nuw i32 [[TMP0:%.*]], 7
+; CHECK-NEXT:    [[TMP3:%.*]] = tail call { i32, i1 } @llvm.uadd.with.overflow.i32(i32 [[TMP2]], i32 13)
+; CHECK-NEXT:    ret { i32, i1 } [[TMP3]]
+;
+  %2 = add nuw i32 %0, 7
+  %3 = tail call { i32, i1 } @llvm.uadd.with.overflow.i32(i32 %2, i32 13)
+  ret { i32, i1 } %3
+}
+
+define { i8, i1 } @fold_on_constant_add_no_overflow(i8) {
+; CHECK-LABEL: @fold_on_constant_add_no_overflow(
+; CHECK-NEXT:    [[TMP2:%.*]] = add nuw i8 [[TMP0:%.*]], -56
+; CHECK-NEXT:    [[TMP3:%.*]] = tail call { i8, i1 } @llvm.uadd.with.overflow.i8(i8 [[TMP2]], i8 55)
+; CHECK-NEXT:    ret { i8, i1 } [[TMP3]]
+;
+  %2 = add nuw i8 %0, 200
+  %3 = tail call { i8, i1 } @llvm.uadd.with.overflow.i8(i8 %2, i8 55)
+  ret { i8, i1 } %3
+}
+
+define { i8, i1 } @no_fold_on_constant_add_overflow(i8) {
+; CHECK-LABEL: @no_fold_on_constant_add_overflow(
+; CHECK-NEXT:    [[TMP2:%.*]] = add nuw i8 [[TMP0:%.*]], -56
+; CHECK-NEXT:    [[TMP3:%.*]] = tail call { i8, i1 } @llvm.uadd.with.overflow.i8(i8 [[TMP2]], i8 56)
+; CHECK-NEXT:    ret { i8, i1 } [[TMP3]]
+;
+  %2 = add nuw i8 %0, 200
+  %3 = tail call { i8, i1 } @llvm.uadd.with.overflow.i8(i8 %2, i8 56)
+  ret { i8, i1 } %3
+}
+
+define { <2 x i32>, <2 x i1> } @fold_simple_splat_constant(<2 x i32>) {
+; CHECK-LABEL: @fold_simple_splat_constant(
+; CHECK-NEXT:    [[TMP2:%.*]] = add nuw <2 x i32> [[TMP0:%.*]], <i32 12, i32 12>
+; CHECK-NEXT:    [[TMP3:%.*]] = tail call { <2 x i32>, <2 x i1> } @llvm.uadd.with.overflow.v2i32(<2 x i32> [[TMP2]], <2 x i32> <i32 30, i32 30>)
+; CHECK-NEXT:    ret { <2 x i32>, <2 x i1> } [[TMP3]]
+;
+  %2 = add nuw <2 x i32> %0, <i32 12, i32 12>
+  %3 = tail call { <2 x i32>, <2 x i1> } @llvm.uadd.with.overflow.v2i32(<2 x i32> %2, <2 x i32> <i32 30, i32 30>)
+  ret { <2 x i32>, <2 x i1> } %3
+}
+
+define { <2 x i32>, <2 x i1> } @no_fold_splat_undef_constant(<2 x i32>) {
+; CHECK-LABEL: @no_fold_splat_undef_constant(
+; CHECK-NEXT:    [[TMP2:%.*]] = add nuw <2 x i32> [[TMP0:%.*]], <i32 12, i32 undef>
+; CHECK-NEXT:    [[TMP3:%.*]] = tail call { <2 x i32>, <2 x i1> } @llvm.uadd.with.overflow.v2i32(<2 x i32> [[TMP2]], <2 x i32> <i32 30, i32 30>)
+; CHECK-NEXT:    ret { <2 x i32>, <2 x i1> } [[TMP3]]
+;
+  %2 = add nuw <2 x i32> %0, <i32 12, i32 undef>
+  %3 = tail call { <2 x i32>, <2 x i1> } @llvm.uadd.with.overflow.v2i32(<2 x i32> %2, <2 x i32> <i32 30, i32 30>)
+  ret { <2 x i32>, <2 x i1> } %3
+}
+
+define { <2 x i32>, <2 x i1> } @no_fold_splat_not_constant(<2 x i32>, <2 x i32>) {
+; CHECK-LABEL: @no_fold_splat_not_constant(
+; CHECK-NEXT:    [[TMP3:%.*]] = add nuw <2 x i32> [[TMP0:%.*]], [[TMP1:%.*]]
+; CHECK-NEXT:    [[TMP4:%.*]] = tail call { <2 x i32>, <2 x i1> } @llvm.uadd.with.overflow.v2i32(<2 x i32> [[TMP3]], <2 x i32> <i32 30, i32 30>)
+; CHECK-NEXT:    ret { <2 x i32>, <2 x i1> } [[TMP4]]
+;
+  %3 = add nuw <2 x i32> %0, %1
+  %4 = tail call { <2 x i32>, <2 x i1> } @llvm.uadd.with.overflow.v2i32(<2 x i32> %3, <2 x i32> <i32 30, i32 30>)
+  ret { <2 x i32>, <2 x i1> } %4
+}
+
+define { i32, i1 } @fold_nuwnsw(i32) {
+; CHECK-LABEL: @fold_nuwnsw(
+; CHECK-NEXT:    [[TMP2:%.*]] = add nuw nsw i32 [[TMP0:%.*]], 12
+; CHECK-NEXT:    [[TMP3:%.*]] = tail call { i32, i1 } @llvm.uadd.with.overflow.i32(i32 [[TMP2]], i32 30)
+; CHECK-NEXT:    ret { i32, i1 } [[TMP3]]
+;
+  %2 = add nuw nsw i32 %0, 12
+  %3 = tail call { i32, i1 } @llvm.uadd.with.overflow.i32(i32 %2, i32 30)
+  ret { i32, i1 } %3
+}
+
+define { i32, i1 } @no_fold_nsw(i32) {
+; CHECK-LABEL: @no_fold_nsw(
+; CHECK-NEXT:    [[TMP2:%.*]] = add nsw i32 [[TMP0:%.*]], 12
+; CHECK-NEXT:    [[TMP3:%.*]] = tail call { i32, i1 } @llvm.uadd.with.overflow.i32(i32 [[TMP2]], i32 30)
+; CHECK-NEXT:    ret { i32, i1 } [[TMP3]]
+;
+  %2 = add nsw i32 %0, 12
+  %3 = tail call { i32, i1 } @llvm.uadd.with.overflow.i32(i32 %2, i32 30)
+  ret { i32, i1 } %3
+}