[gn build] Make `ninja check-lld` also run LLD's unit tests

[thakis]

Summary

And add build files for gtest.

Goes on top of https://reviews.llvm.org/D55836

With this, the build files for //lld are complete.

[phosek]

LGTM

llvm/utils/gn/secondary/lld/unittests/DriverTests/BUILD.gn

2 ↗

(On Diff #178722)

If this becomes common we should consider introducing a test template.

[thakis]

Thanks! Actually landing this is blocked on https://reviews.llvm.org/D55836 though.

llvm/utils/gn/secondary/lld/unittests/DriverTests/BUILD.gn

2 ↗

(On Diff #178722)

Every unit test looks like this, so this is a good idea. I'll add a template when I add unit tests for llvm or clang, whatever comes first. (LLD only has two unit test binaries, so waiting until then seems fine to me.)

llvm/trunk/utils/gn/secondary/lld/test/BUILD.gn

 # This target should contain all dependencies of check-lld.
 # //:default depends on it, so that ninja's default target builds all
 # prerequisites for check-lld but doesn't run check-lld itself.
 group("test") {
   deps = [
     ":lit_site_cfg",
     ":lit_unit_site_cfg",
     "//lld/tools/lld:symlinks",
+    "//lld/unittests",
     "//llvm/tools/llc",
     "//llvm/tools/llvm-ar:symlinks",
     "//llvm/tools/llvm-as",
     "//llvm/tools/llvm-bcanalyzer",
     "//llvm/tools/llvm-dis",
     "//llvm/tools/llvm-dwarfdump",
     "//llvm/tools/llvm-mc",
     "//llvm/tools/llvm-nm:symlinks",
     "//llvm/tools/llvm-objcopy:symlinks",
     "//llvm/tools/llvm-objdump:symlinks",
     "//llvm/tools/llvm-pdbutil",
     "//llvm/tools/llvm-readobj:symlinks",
     "//llvm/tools/obj2yaml",
     "//llvm/tools/opt",
     "//llvm/tools/yaml2obj",
     "//llvm/utils/FileCheck",
     "//llvm/utils/count",
     "//llvm/utils/llvm-lit",
     "//llvm/utils/not",
   ]
   testonly = true
-
-  # FIXME: Add dep on "//lld/unittests" target once it exists.
 }
 
 # This is the action that runs all of lld's tests, check-lld.
 action("check-lld") {
   script = "$root_out_dir/bin/llvm-lit"
   if (host_os == "win") {
     script += ".py"
   }

llvm/trunk/utils/gn/secondary/lld/unittests/BUILD.gn

+group("unittests") {
+  deps = [
+    "DriverTests",
+    "MachOTests",
+  ]
+  testonly = true
+}

llvm/trunk/utils/gn/secondary/lld/unittests/DriverTests/BUILD.gn

+executable("DriverTests") {
+  # test/Unit/lit.cfg expects unittests in LLD_BINARY_DIR/unittest
+  output_dir = target_out_dir
+
+  configs += [ "//llvm/utils/gn/build:lld_code" ]
+  deps = [
+    "//lld/lib/Driver",
+    "//lld/lib/ReaderWriter/MachO",
+    "//llvm/utils/unittest/UnitTestMain",
+  ]
+  sources = [
+    "DarwinLdDriverTest.cpp",
+  ]
+  testonly = true
+}

llvm/trunk/utils/gn/secondary/lld/unittests/MachOTests/BUILD.gn

+executable("MachOTests") {
+  # test/Unit/lit.cfg expects unittests in LLD_BINARY_DIR/unittest
+  output_dir = target_out_dir
+
+  configs += [ "//llvm/utils/gn/build:lld_code" ]
+  deps = [
+    "//lld/lib/Driver",
+    "//lld/lib/ReaderWriter/MachO",
+    "//lld/lib/ReaderWriter/YAML",
+    "//llvm/utils/unittest/UnitTestMain",
+  ]
+  sources = [
+    "MachONormalizedFileBinaryReaderTests.cpp",
+    "MachONormalizedFileBinaryWriterTests.cpp",
+    "MachONormalizedFileToAtomsTests.cpp",
+    "MachONormalizedFileYAMLTests.cpp",
+  ]
+  testonly = true
+}

llvm/trunk/utils/gn/secondary/llvm/utils/unittest/BUILD.gn

+import("//llvm/utils/gn/build/libs/pthread/enable.gni")
+
+# Used to push the gtest include directories to things depending on :googletest.
+config("googletest_config") {
+  include_dirs = [
+    "googlemock/include",
+    "googletest/include",
+  ]
+
+  # LLVM requires C++11 but gtest doesn't correctly detect the availability
+  # of C++11 on MSVC, so we force it on.
+  defines = [
+    "GTEST_LANG_CXX11",
+    "GTEST_HAS_TR1_TUPLE=0",
+  ]
+  if (host_os == "win") {
+    defines += [ "GTEST_OS_WINDOWS" ]
+  }
+  if (!llvm_enable_threads) {
+    defines += [ "GTEST_HAS_PTHREAD=0" ]
+  }
+  defines += [ "GTEST_HAS_RTTI=0" ]
+}
+
+static_library("gtest") {
+  deps = [
+    "//llvm/lib/Support",
+  ]
+  include_dirs = [
+    "googletest",  # For including src/gtest.cc
+    "googlemock",  # For including src/gmock.cc
+  ]
+  public_configs = [ ":googletest_config" ]
+  configs -= [ "//llvm/utils/gn/build:warn_covered_switch_default" ]
+  sources = [
+    "googlemock/src/gmock-all.cc",
+    "googletest/src/gtest-all.cc",
+  ]
+  testonly = true
+}

llvm/trunk/utils/gn/secondary/llvm/utils/unittest/UnitTestMain/BUILD.gn

+source_set("UnitTestMain") {
+  deps = [
+    "//llvm/lib/Support",
+  ]
+
+  # Make targets depending on this also depend on gtest, to get the gtest
+  # include_dir.
+  public_deps = [
+    "..:gtest",
+  ]
+  sources = [
+    "TestMain.cpp",
+  ]
+  testonly = true
+}
+
+# Nothing depends on this target, but llvm-config expects it to exist when
+# it runs with `--link-static --system-libs`, so humor it.
+static_library("gtest_main") {
+  deps = [
+    ":UnitTestMain",
+  ]
+  complete_static_lib = true
+  testonly = true
+}