gn build: Add support for building the standalone ubsan runtime as a shared library on non-Mac.

[pcc]

Summary

Builds on Mac and Linux, disabled on Windows.

[thakis]

lg, please watch http://45.33.8.238/ after landing (especially the non-linux bots)

llvm/utils/gn/secondary/compiler-rt/lib/ubsan/BUILD.gn

130

Should this be gated on !is_mac && !is_win or similar?

[pcc]

llvm/utils/gn/secondary/compiler-rt/lib/ubsan/BUILD.gn

130

Yes, but with my changes to lib/BUILD.gn we weren't building this for Windows with this patch. I'll change lib/BUILD.gn to try building for Windows before I submit and roll that back if it doesn't work.

[pcc]

Fix Mac build

[pcc]

Looks like this never got approved and a different set of patches landed instead which didn't include shared library support :(

[pcc]

Rebased this patch by first reverting the other ubsan patches

llvm/utils/gn/secondary/compiler-rt/gen_version_script.gni

+import("//compiler-rt/target.gni")
+
+template("gen_version_script") {
+  action(target_name) {
+    script = "//compiler-rt/lib/sanitizer_common/scripts/gen_dynamic_list.py"
+    sources = [ invoker.extra ]
+    deps = invoker.libs
+    outputs = [ invoker.output ]
+    args = [
+      "--version-list",
+      "--extra",
+      rebase_path(invoker.extra, root_build_dir),
+    ]
+    foreach (lib_name, invoker.lib_names) {
+      args += [
+      rebase_path(
+          "$crt_current_out_dir/libclang_rt.$lib_name$crt_current_target_suffix.a",
+          root_build_dir)
+          ]
+    }
+    args += [
+      "--nm-executable",
+      "nm",
+      "-o",
+      rebase_path(invoker.output, root_build_dir),
+    ]
+  }
+}

llvm/utils/gn/secondary/compiler-rt/lib/BUILD.gn

if (current_os != "win" && current_os != "baremetal") {
     if (current_cpu == "x64" || current_cpu == "arm64") {
       deps += [ "//compiler-rt/lib/tsan/rtl" ]
     }
   }
   if (current_os != "win") {
     deps += [ "//compiler-rt/lib/builtins" ]
   }
   if (current_os != "baremetal") {
-    deps += [ "//compiler-rt/lib/profile" ]
+    deps += [
+      "//compiler-rt/lib/profile",
+      "//compiler-rt/lib/ubsan:ubsan_shared",
+    ]
   }
 }

llvm/utils/gn/secondary/compiler-rt/lib/hwasan/BUILD.gn

+import("//compiler-rt/gen_version_script.gni")
 import("//compiler-rt/target.gni")
 
 if (current_cpu == "x64") {
   hwasan_name = "hwasan_aliases"
 } else {
   hwasan_name = "hwasan"
 }
 
-action("version_script") {
-  script = "//compiler-rt/lib/sanitizer_common/scripts/gen_dynamic_list.py"
-  sources = [ "hwasan.syms.extra" ]
-  deps = [
+gen_version_script("version_script") {
+  extra = "hwasan.syms.extra"
+  output = "$target_gen_dir/hwasan.vers"
+  libs = [
     ":hwasan",
     ":hwasan_cxx",
   ]
-  outputs = [ "$target_gen_dir/hwasan.vers" ]
-  args = [
-    "--version-list",
-    "--extra",
-    rebase_path(sources[0], root_build_dir),
-    rebase_path(
-        "$crt_current_out_dir/libclang_rt.$hwasan_name$crt_current_target_suffix.a",
-        root_build_dir),
-    rebase_path(
-        "$crt_current_out_dir/libclang_rt.${hwasan_name}_cxx$crt_current_target_suffix.a",
-        root_build_dir),
-    "--nm-executable",
-    "nm",
-    "-o",
-    rebase_path(outputs[0], root_build_dir),
+  lib_names = [
+    "$hwasan_name",
+    "${hwasan_name}_cxx",
   ]
 }
 
 source_set("sources") {
   configs -= [ "//llvm/utils/gn/build:llvm_code" ]
   configs += [ "//llvm/utils/gn/build:crt_code" ]
   defines = [ "HWASAN_WITH_INTERCEPTORS=1" ]
   if (current_cpu == "x64") {

llvm/utils/gn/secondary/compiler-rt/lib/ubsan/BUILD.gn

+import("//compiler-rt/gen_version_script.gni")
+import("//compiler-rt/target.gni")
+
+gen_version_script("version_script") {
+  extra = "ubsan.syms.extra"
+  output = "$target_gen_dir/ubsan.vers"
+  libs = [
+    ":ubsan",
+    ":ubsan_cxx",
+  ]
+  lib_names = [
+    "ubsan_standalone",
+    "ubsan_standalone_cxx",
+  ]
+}
+
 source_set("sources") {
   configs -= [ "//llvm/utils/gn/build:llvm_code" ]
   configs += [ "//llvm/utils/gn/build:crt_code" ]
   defines = [ "UBSAN_CAN_USE_CXXABI" ]
   deps = [
     "//compiler-rt/lib/interception:sources",
     "//compiler-rt/lib/sanitizer_common:sources",
   ]

 
 source_set("dynamic_runtime_thunk") {
   configs -= [ "//llvm/utils/gn/build:llvm_code" ]
   configs += [ "//llvm/utils/gn/build:crt_code" ]
   defines = [ "SANITIZER_DYNAMIC_RUNTIME_THUNK" ]
   sources = [ "ubsan_win_dynamic_runtime_thunk.cpp" ]
 }
 
-# Unreferenced; at the moment exists to make sync_source_lists_from_cmake happy.
 source_set("standalone_sources") {
   configs -= [ "//llvm/utils/gn/build:llvm_code" ]
   configs -= [ "//llvm/utils/gn/build:no_rtti" ]
   configs += [ "//llvm/utils/gn/build:crt_code" ]
   defines = [ "UBSAN_CAN_USE_CXXABI" ]
   sources = [
     "ubsan_diag_standalone.cpp",
     "ubsan_init_standalone.cpp",
source_set("cxx_sources") {
   sources = [
     "ubsan_handlers_cxx.cpp",
     "ubsan_handlers_cxx.h",
     "ubsan_type_hash.cpp",
     "ubsan_type_hash_itanium.cpp",
     "ubsan_type_hash_win.cpp",
   ]
 }
+
+static_library("ubsan") {
+  output_dir = crt_current_out_dir
+  output_name = "clang_rt.ubsan_standalone$crt_current_target_suffix"
+  complete_static_lib = true
+  configs -= [
+    "//llvm/utils/gn/build:llvm_code",
+    "//llvm/utils/gn/build:thin_archive",
+  ]
+  configs += [ "//llvm/utils/gn/build:crt_code" ]
+  deps = [
+    ":sources",
+    ":standalone_sources",
+  ]
+}
+
+static_library("ubsan_cxx") {
+  output_dir = crt_current_out_dir
+  output_name = "clang_rt.ubsan_standalone_cxx$crt_current_target_suffix"
+  complete_static_lib = true
+  configs -= [
+    "//llvm/utils/gn/build:llvm_code",
+    "//llvm/utils/gn/build:thin_archive",
+  ]
+  configs += [ "//llvm/utils/gn/build:crt_code" ]
+  deps = [ ":cxx_sources" ]
+}
+
+shared_library("ubsan_shared") {
+  output_dir = crt_current_out_dir
+  output_name = "clang_rt.ubsan_standalone$crt_current_target_suffix"
+  configs -= [ "//llvm/utils/gn/build:llvm_code" ]
+  configs += [ "//llvm/utils/gn/build:crt_code" ]
+  deps = [
+    ":cxx_sources",
+    ":sources",
+    ":standalone_sources",
+  ]
+  if (current_os != "mac" && current_os != "win") {
+    deps += [ ":version_script" ]
+    inputs = [ "$target_gen_dir/ubsan.vers" ]
+    ldflags =
+        [ "-Wl,--version-script," + rebase_path(inputs[0], root_build_dir) ]
+  }
+}