[gn build] (manually) port some more of cd2292ef8245

[thakis]

Summary

For demo purposes only at the moment. Will land something like that once tests need it.

[thakis]

Landed in bacb56cdc593e054db33c4aecb57cbbe9c20f4d6 (with some tweaks) for use in 12109a3b40e3107ab11d6b92c57f04f4d985230e

llvm/utils/gn/secondary/clang-tools-extra/pseudo/cxx/BUILD.gn

-# FIXME: Nothing depends on this yet.
-static_library("cxx") {
-  output_name = "clangPseudoCXX"
-  configs += [ "//llvm/utils/gn/build:clang_code" ]
-  deps = [ "//clang-tools-extra/pseudo/lib/grammar" ]
-  sources = [ "CXX.cpp" ]
-}

llvm/utils/gn/secondary/clang-tools-extra/pseudo/include/BUILD.gn

+import("//llvm/utils/gn/build/compiled_action.gni")
+
+template("gen") {
+  compiled_action(target_name) {
+    tool = "//clang-tools-extra/pseudo/gen:pseudo-gen"
+    inputs = [ "../lib/cxx.bnf" ]
+    outputs = [ "$target_gen_dir/$target_name" ]
+    args = [
+      "--grammar",
+      rebase_path(inputs[0], root_build_dir),
+      "-o",
+      rebase_path(outputs[0], root_build_dir),
+      invoker.flag,
+    ]
+  }
+}
+
+gen("CXXSymbols.inc") {
+  flag = "--emit-symbol-list"
+}
+
+gen("CXXBNF.inc") {
+  flag = "--emit-grammar-content"
+}
+
+config("cxx_gen_config") {
+  visibility = [ ":cxx_gen" ]
+  include_dirs = [ target_gen_dir ]
+}
+
+group("cxx_gen") {
+  deps = [
+    ":CXXSymbols.inc",
+    ":CXXBNF.inc",
+  ]
+
+  # Let targets depending on this find the generated files.
+  public_configs = [ ":cxx_gen_config" ]
+}

llvm/utils/gn/secondary/clang-tools-extra/pseudo/lib/cxx/BUILD.gn

+static_library("cxx") {
+  output_name = "clangPseudoCXX"
+  configs += [ "//llvm/utils/gn/build:clang_code" ]
+  deps = [
+    "//clang-tools-extra/pseudo/include:cxx_gen",
+    "//clang-tools-extra/pseudo/lib/grammar",
+  ]
+  include_dirs = [ "../../include" ]
+  sources = [ "CXX.cpp" ]
+}

llvm/utils/gn/secondary/clang-tools-extra/pseudo/test/BUILD.gn

 # //:default depends on it, so that ninja's default target builds all
 # prerequisites for check-clang but doesn't run check-clang itself.
 group("test") {
   deps = [
     ":lit_site_cfg",
     ":lit_unit_site_cfg",
     "//clang-tools-extra/pseudo/tool:clang-pseudo",
     "//clang-tools-extra/pseudo/unittests:ClangPseudoTests",
+    "//clang-tools-extra/pseudo/lib/cxx",
     "//llvm/utils/FileCheck",
     "//llvm/utils/llvm-lit",
     "//llvm/utils/not",
   ]
   testonly = true
 }
 
 action("check-clang-pseudo") {