[gn build] Don't pass -Wl,-z,defs for sanitizer builds

[aeubanks]

Summary

-Wl,-z,defs doesn't work with sanitizers.
See https://clang.llvm.org/docs/AddressSanitizer.html

[thakis]

llvm/utils/gn/build/BUILD.gn

374

Only on Linux (or non-win non-mac non-ios i guess. Maybe non-android non-fuchsia too, not sure there without looking it up)

Also, do we need a separate config for this? Can we edit llvm/utils/gn/build/BUILD.gn around line 91 and put something like

if (current_os != "ios" && current_os != "mac" && !(current_os == "linux" && (use_asan || use_tsan || use_ubsan))) {
  ldflags += [ "-Wl,-z,defs" ]
}

there?

(Things only go in configs if some configs need to opt out of them, which here doesn't seem to be the case as far as I can tell.)

[aeubanks]

check current_os

llvm/utils/gn/build/BUILD.gn

374

I initially did put it there, but that adds -Wl,-z,defs to static links as well, which doesn't change anything but makes the command line a bit longer. If that's fine with you though I can do that.

[thakis]

Oh I see, that makes sense.

llvm/utils/gn/build/BUILD.gn

config("no_rtti") {
   if (current_os == "win") {
     cflags_cc = [ "/GR-" ]
   } else {
     cflags_cc = [ "-fno-rtti" ]
   }
   cflags_objcc = cflags_cc
 }
 
+config("zdefs") {
+  # -Wl,-z,defs doesn't work with sanitizers.
+  # https://clang.llvm.org/docs/AddressSanitizer.html
+  if (current_os != "ios" && current_os != "mac" && current_os != "win" && !(use_asan || use_tsan || use_ubsan)) {
+    ldflags = [ "-Wl,-z,defs" ]
+  }
+}
+
 # To make an archive that can be distributed, you need to remove this config and
 # set complete_static_lib.
 config("thin_archive") {
   if (current_os != "ios" && current_os != "mac" && current_os != "win") {
     arflags = [ "-T" ]
   }
 }
 

llvm/utils/gn/build/BUILDCONFIG.gn

 }
 set_defaults("loadable_module") {
   configs = shared_binary_target_configs
 }
 set_defaults("static_library") {
   configs = shared_binary_target_configs
 }
 set_defaults("shared_library") {
-  configs = shared_binary_target_configs
+  configs = shared_binary_target_configs + [ "//llvm/utils/gn/build:zdefs" ]
 }
 set_defaults("source_set") {
   configs = shared_binary_target_configs
 }
 
 if (target_os == "") {
   target_os = host_os
 }

llvm/utils/gn/build/toolchain/BUILD.gn

toolchain(target_name) {
     lib_dir_switch = "-L"
 
     tool("solink") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
       if (current_os == "ios" || current_os == "mac") {
         command = "$ld -shared {{ldflags}} -o $outfile {{inputs}} {{libs}} {{frameworks}}"
         default_output_extension = ".dylib"
       } else {
-        command = "$ld -shared {{ldflags}} -Wl,-z,defs -Wl,-soname,{{target_output_name}}{{output_extension}} -o $outfile {{inputs}} {{libs}}"
+        command = "$ld -shared {{ldflags}} -Wl,-soname,{{target_output_name}}{{output_extension}} -o $outfile {{inputs}} {{libs}}"
         default_output_extension = ".so"
       }
       description = "SOLINK $outfile"
       outputs = [ outfile ]
       output_prefix = "lib"
       default_output_dir = "{{root_out_dir}}/lib"
     }