gn build: Add support for building LLDB on Linux.

[pcc]

Summary

On Linux, LLDB depends on lldb-server at runtime (is it different on
Mac?), so I created a top-level lldb target that will build both lldb
and lldb-server.

[thakis]

Very cool. LG with top-level BUILD.gn comment addressed :)

llvm/utils/gn/secondary/BUILD.gn

15

Does this build fine on windows?

Generally this only depends on the test targets which in turn depend on the binaries, so probably should only have the old/test dep in this file anyways.

[pcc]

llvm/utils/gn/secondary/BUILD.gn

15

You're right, this needs to avoid the dependency on lldb on Windows targets.

The problem with only depending on //lldb/test is that nothing else refers to //lldb, so ninja lldb wouldn't also build lldb-server. Maybe it would be better to add lldb-server to the data_deps of //lldb/tools/driver:lldb instead then.

[pcc]

Move to data_deps

[thakis]

llvm/utils/gn/secondary/BUILD.gn

15

I guess //lldb/test could depend on //:lldb instead of //lldb/tools/driver?

We currently don't use data_deps anywhere else. (I have https://github.com/nico/llvm-project/commit/7246393c6bbc270044641415ffb0db93ffee3e29 on a branch, but uploads with static links take so long that it isn't really worth it. Maybe I should revisit that with -fno-semantic-interposition…)

[pcc]

llvm/utils/gn/secondary/BUILD.gn

15

And then //:lldb would depend on lldb and the various lldb-servers? I suppose that could work.

It seems like clang's existing dependency on e.g. clang-offload-bundler, which is the sort of dependency we want here, is currently added via deps, and I see that your change moves that to data_deps. For executable->executable dependencies I suppose that deps means the same thing as data_deps (test isolation aside) but to be consistent with what's in clang maybe we should just stick to what I have here except with s/data_deps/deps/g.

[thakis]

llvm/utils/gn/secondary/BUILD.gn

15

sgtm.

[thakis]

(Please watch http://45.33.8.238/ when landing this :) )

llvm/utils/gn/secondary/BUILD.gn

 import("//clang/lib/ARCMigrate/enable.gni")
 import("//clang/lib/StaticAnalyzer/Frontend/enable.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 
 group("default") {
   deps = [
     "//clang-tools-extra/clangd/test",
     "//clang-tools-extra/test",
     "//clang/test",
     "//clang/tools/scan-build",
     "//compiler-rt",
     "//compiler-rt/include",
     "//compiler-rt/lib/scudo",
     "//lld/test",
     "//llvm/test",
   ]
   if (current_os == "linux") {
     deps += [
       "//libcxx",
       "//libcxxabi",
     ]
   }
-  if (current_os == "mac") {
+  if (current_os == "linux" || current_os == "mac") {
     deps += [ "//lldb/test" ]
   }
   if (current_os == "linux" || current_os == "android") {
     deps += [ "//compiler-rt/test/hwasan" ]
   }
   if (current_os == "linux" || current_os == "mac") {
     deps += [ "//libunwind" ]
   }

llvm/utils/gn/secondary/lldb/include/lldb/Host/BUILD.gn

 import("//llvm/utils/gn/build/libs/xml/enable.gni")
 import("//llvm/utils/gn/build/write_cmake_config.gni")
 import("libedit.gni")
 
 # In lldb/cmake/modules/LLDBGenerateConfig.cmake,
 # brought in by lldb/cmake/modules/LLDBConfig.cmake,
 # brought in by lldb/CMakeLists.txt in the CMake build.
 write_cmake_config("Config") {
   input = "Config.h.cmake"
   output = "$target_gen_dir/Config.h"
   values = [
     # FIXME: Actual values for everything.
     "LLDB_EDITLINE_USE_WCHAR=",
     "LLDB_HAVE_EL_RFUNC_T=",
-    "HAVE_PPOLL=",
     "HAVE_PTSNAME_R=",
     "HAVE_PROCESS_VM_READV=",
     "HAVE_NR_PROCESS_VM_READV=",
     "LLDB_ENABLE_LZMA=",
     "LLDB_ENABLE_CURSES=",
     "CURSES_HAVE_NCURSES_CURSES_H=",
     "LLDB_ENABLE_LUA=",
     "LLDB_ENABLE_PYTHON=",
write_cmake_config("Config") {
   if (llvm_enable_libxml2) {
     values += [ "LLDB_ENABLE_LIBXML2=1" ]
   } else {
     values += [ "LLDB_ENABLE_LIBXML2=" ]
   }
 
   if (current_os == "win") {
     values += [
-      "HAVE_SYS_EVENT_H=",
       "LLDB_ENABLE_POSIX=",
       "LLDB_ENABLE_TERMIOS=",
     ]
   } else {
     values += [
-      "HAVE_SYS_EVENT_H=1",
       "LLDB_ENABLE_POSIX=1",
       "LLDB_ENABLE_TERMIOS=1",
     ]
   }
+  
+  if (current_os == "win" || current_os == "linux" || current_os == "android") {
+    values += [ "HAVE_SYS_EVENT_H=" ]
+  } else {
+    values += [ "HAVE_SYS_EVENT_H=1" ]
+  }
+
+  if (current_os == "linux" || current_os == "android") {
+    values += [ "HAVE_PPOLL=1" ]
+  } else {
+    values += [ "HAVE_PPOLL=" ]
+  }
 }

llvm/utils/gn/secondary/lldb/source/Initialization/BUILD.gn

 static_library("Initialization") {
   output_name = "lldbInitialization"
   configs += [ "//llvm/utils/gn/build:lldb_code" ]
   deps = [
     "//lldb/source/Core",
     "//lldb/source/Host",
     "//lldb/source/Plugins/Process/gdb-remote",
 
     # XXX:
-    # lldbPluginProcessPOSIX on linux/android
     # lldbPluginProcessWindowsCommon on win
     "//llvm/lib/Support",
   ]
+  if (current_os == "linux" || current_os == "android") {
+    deps += [ "//lldb/source/Plugins/Process/POSIX" ]
+  }
 
   # SystemInitializerCommon.cpp includes headers from Plugins/Process/....
   include_dirs = [ ".." ]
   sources = [
     "SystemInitializer.cpp",
     "SystemInitializerCommon.cpp",
     "SystemLifetimeManager.cpp",
   ]
 }

llvm/utils/gn/secondary/lldb/source/Plugins/BUILD.gn

[
     "//lldb/source/Plugins/ObjectFile/PECOFF",
     "ObjectFilePECOFF",
   ],
   [
     "//lldb/source/Plugins/ObjectFile/wasm",
     "ObjectFileWasm",
   ],
   [
+    "//lldb/source/Plugins/Platform/Linux",
+    "PlatformLinux",
+  ],
+  [
     "//lldb/source/Plugins/Platform/MacOSX",
     "PlatformMacOSX",
   ],
   [
     "//lldb/source/Plugins/Platform/Windows",
     "PlatformWindows",
   ],
   [

llvm/utils/gn/secondary/lldb/source/Plugins/ObjectFile/JIT/BUILD.gn

 static_library("JIT") {
   output_name = "lldbPluginObjectFileJIT"
   configs += [ "//llvm/utils/gn/build:lldb_code" ]
   deps = [
     "//lldb/source/Core",
     "//lldb/source/Host",
 
     #"//lldb/source/Symbol", # 2-hop dependency cycle.
     #"//lldb/source/Target", # 2-hop dependency cycle.
     "//llvm/lib/Support",
   ]
   sources = [ "ObjectFileJIT.cpp" ]
+  # For Utility/UuidCompatibility.h.
+  include_dirs = [ "//lldb/source" ]
 }

llvm/utils/gn/secondary/lldb/source/Plugins/Platform/Linux/BUILD.gn

+static_library("Linux") {
+  output_name = "lldbPluginPlatformLinux"
+  configs += [
+    "//llvm/utils/gn/build:clang_code",
+    "//llvm/utils/gn/build:lldb_code",
+  ]
+  deps = [
+    "//lldb/source/Breakpoint",
+    "//lldb/source/Core",
+    "//lldb/source/Host",
+    "//lldb/source/Interpreter",
+    "//lldb/source/Target",
+    "//lldb/source/Plugins/Platform/POSIX",
+  ]
+  # Reaches into Plugins/Platform/POSIX.
+  include_dirs = [ "//lldb/source" ]
+  sources = [ "PlatformLinux.cpp" ]
+}

llvm/utils/gn/secondary/lldb/source/Plugins/Process/Linux/BUILD.gn

+static_library("Linux") {
+  output_name = "lldbPluginProcessLinux"
+  configs += [ "//llvm/utils/gn/build:lldb_code" ]
+  deps = [
+    "//lldb/source/Core",
+    "//lldb/source/Host",
+    "//lldb/source/Symbol",
+    "//lldb/source/Target",
+    "//lldb/source/Utility",
+    "//lldb/source/Plugins/Process/POSIX",
+    "//lldb/source/Plugins/Process/Utility",
+    "//llvm/lib/Support",
+  ]
+  # Uses source-relative includes for own headers.
+  include_dirs = [ "//lldb/source" ]
+  sources = [
+    "IntelPTManager.cpp",
+    "NativeProcessLinux.cpp",
+    "NativeRegisterContextLinux.cpp",
+    "NativeRegisterContextLinux_arm.cpp",
+    "NativeRegisterContextLinux_arm64.cpp",
+    "NativeRegisterContextLinux_ppc64le.cpp",
+    "NativeRegisterContextLinux_s390x.cpp",
+    "NativeRegisterContextLinux_x86_64.cpp",
+    "NativeThreadLinux.cpp",
+    "SingleStepCheck.cpp",
+  ]
+}
+

llvm/utils/gn/secondary/lldb/source/Plugins/Process/POSIX/BUILD.gn

+static_library("POSIX") {
+  output_name = "lldbPluginProcessPOSIX"
+  configs += [ "//llvm/utils/gn/build:lldb_code" ]
+  deps = [
+    "//lldb/source/Utility",
+    "//lldb/source/Plugins/Process/Utility",
+    "//llvm/lib/Support",
+  ]
+  # Reaches into Plugins/Platform/Process/Utility.
+  include_dirs = [ "//lldb/source" ]
+  sources = [
+    "CrashReason.cpp",
+    "NativeProcessELF.cpp",
+    "ProcessMessage.cpp",
+    "ProcessPOSIXLog.cpp",
+  ]
+}

llvm/utils/gn/secondary/lldb/tools/driver/BUILD.gn

 import("//llvm/utils/TableGen/tablegen.gni")
 import("//llvm/utils/gn/build/write_cmake_config.gni")
 import("//llvm/version.gni")
 
 tablegen("Options") {
   visibility = [ ":lldb" ]
   args = [ "-gen-opt-parser-defs" ]
 }
 
-if (host_os == "mac") {
+if (current_os == "mac") {
   write_cmake_config("write_info_plist") {
     input = "lldb-Info.plist.in"
     output = "$target_gen_dir/lldb-Info.plist"
     values = [ "LLDB_VERSION=$llvm_version" ]
   }
 }
 
 executable("lldb") {
   configs += [ "//llvm/utils/gn/build:lldb_code" ]
   deps = [
     ":Options",
     "//lldb/include/lldb/Host:Config",
     "//lldb/source/API:liblldb",
     "//llvm/lib/Option",
     "//llvm/lib/Support",
     "//llvm/utils/gn/build/libs/xar",
   ]
-  if (host_os == "mac") {
+  if (current_os == "mac") {
     deps += [ ":write_info_plist" ]
     plist = get_target_outputs(":write_info_plist")
     ldflags = [ "-Wl,-sectcreate,__TEXT,__info_plist," +
                 rebase_path(plist[0], root_out_dir) ]
   }
+  if (current_os == "linux") {
+    deps += [ "//lldb/tools/lldb-server" ]
+  }
 
   sources = [
     "Driver.cpp",
     "Platform.cpp",
   ]
 
   # XXX if win -DIMPORT_LIBLLDB
   # XXX LLDB_BUILD_FRAMEWORK rpath stuff
 }

llvm/utils/gn/secondary/lldb/tools/lldb-server/BUILD.gn

deps = [
     "//llvm/lib/Option",
     "//llvm/lib/Support",
 
     # Dep of //lldb/source/Core, but omitted there due to a
     # dependency cyle. Need to add dep here.
     "//lldb/source/Plugins/Language/CPlusPlus",
   ]
 
-  #if (current_os == "android" || current_os == "linux") {
-    #deps += [ "//lldb/source/Plugins/Process/Linux" ]
+  if (current_os == "android" || current_os == "linux") {
+    deps += [ "//lldb/source/Plugins/Process/Linux" ]
     #} else if (current_os == "freebsd") {
     #deps += [ "//lldb/source/Plugins/Process/FreeBSD" ]
     #} else if (current_os == "netbsd") {
     #deps += [ "//lldb/source/Plugins/Process/NetBSD" ]
-  #}
+  }
 
   if (current_os == "mac") {
     deps += [ "//lldb/source/Plugins/ObjectFile/Mach-O" ]
   } else if (current_os == "win") {
     deps += [ "//lldb/source/Plugins/ObjectFile/PECOFF" ]
   } else {
     deps += [ "//lldb/source/Plugins/ObjectFile/ELF" ]
   }