gn build: Build libclang.so on ELF platforms.

[pcc]

Summary

This requires changing the ELF build to enable -fPIC, consistent
with other platforms.

[thakis]

Hm, I kind of like the PIC-less build. But probably not worth having a toggle for it, I suppose. So lg, but:

llvm/utils/gn/secondary/clang/tools/libclang/BUILD.gn

16

probably should update these too:

% rg -F 'rget_type = "static_librar' llvm/utils/gn
llvm/utils/gn/secondary/compiler-rt/lib/tsan/BUILD.gn
12:  tsan_target_type = "static_library"

llvm/utils/gn/secondary/compiler-rt/lib/asan/BUILD.gn
12:  asan_target_type = "static_library"

llvm/utils/gn/secondary/clang/tools/libclang/BUILD.gn
16:  libclang_target_type = "static_library"

llvm/utils/gn/secondary/llvm/tools/lto/BUILD.gn
8:  lto_target_type = "static_library"

[pcc]

Also libLTO.so

[pcc]

llvm/utils/gn/secondary/clang/tools/libclang/BUILD.gn

16

Done for llvm/tools/lto.

For the sanitizers the shared-ness of the runtime is tied to what works best on that platform, rather than whether it's PIC by default (note that all compiler-rt code is built with -fPIC), so I left them as is.

[thakis]

llvm/utils/gn/secondary/llvm/tools/lto/BUILD.gn

20

Run gn format before comitting, it'll put this at the top.

llvm/utils/gn/build/BUILD.gn

config("thin_archive") {
   }
 }
 
 config("llvm_code") {
   include_dirs = [
     "//llvm/include",
     "$root_gen_dir/llvm/include",
   ]
+  if (current_os != "win") {
+    cflags = [ "-fPIC" ]
+  }
 }
 
 config("lld_code") {
   include_dirs = [
     "//lld/include",
     "$root_gen_dir/lld/include",
   ]
 }

llvm/utils/gn/secondary/clang/tools/libclang/BUILD.gn

 import("//clang/lib/ARCMigrate/enable.gni")
 import("//llvm/utils/gn/build/symbol_exports.gni")
 import("//llvm/version.gni")
 
 # This build file is just enough to get check-clang to pass, it's missing
 # several things from the CMake build:
 # - a build target copying the Python bindings
-# - the GN linux build always builds without -fPIC (as if LLVM_ENABLE_PIC=OFF
-#   in the CMake build), so libclang is always a static library on linux
 # - the GN build doesn't have LIBCLANG_BUILD_STATIC
 
-libclang_target_type = "shared_library"
-if (host_os != "win" && host_os != "mac") {
-  # ELF targets need -fPIC to build shared libs but they aren't on by default.
-  # For now, make libclang a static lib there.
-  libclang_target_type = "static_library"
-} else {
-  action("linker_script_to_exports") {
-    script = "linker-script-to-export-list.py"
-    inputs = [ "libclang.map" ]
-    outputs = [ "$target_gen_dir/libclang.exports" ]
-    args = [
-      rebase_path(inputs[0], root_build_dir),
-      rebase_path(outputs[0], root_build_dir),
-    ]
-  }
 
-  symbol_exports("exports") {
-    deps = [ ":linker_script_to_exports" ]
-    exports_file = "$target_gen_dir/libclang.exports"
-  }
-}
 
-target(libclang_target_type, "libclang") {
+shared_library("libclang") {
   configs += [ "//llvm/utils/gn/build:clang_code" ]
   deps = [
     "//clang/include/clang/Config",
     "//clang/lib/AST",
     "//clang/lib/Basic",
     "//clang/lib/Frontend",
     "//clang/lib/Headers",
     "//clang/lib/Index",
     "//clang/lib/Lex",
     "//clang/lib/Sema",
     "//clang/lib/Tooling",
     "//llvm/include/llvm/Config:llvm-config",
     "//llvm/lib/IR",
     "//llvm/lib/Support",
     "//llvm/lib/Target:TargetsToBuild",
   ]
+  if (current_os == "win" || current_os == "mac") {
+    deps += [ ":exports" ]
+  } else {
+    inputs = [ "libclang.map" ]
+    ldflags =
+        [ "-Wl,--version-script," + rebase_path(inputs[0], root_build_dir) ]
+  }
   if (clang_enable_arcmt) {
     deps += [ "//clang/lib/ARCMigrate" ]
   }
 
-  if (libclang_target_type == "shared_library") {
-    deps += [ ":exports" ]
-  }
-
   defines = []
 
   if (host_os == "win") {
     defines += [ "_CINDEX_LIB_" ]
   }
 
   sources = [
     "../../include/clang-c/Index.h",

llvm/utils/gn/secondary/llvm/tools/lto/BUILD.gn

 import("//llvm/utils/gn/build/symbol_exports.gni")
 import("//llvm/version.gni")
 
-lto_target_type = "shared_library"
-if (host_os != "mac" && host_os != "win") {
-  # ELF targets need -fPIC to build shared libs but they aren't on by default.
-  # For now, make libclang a static lib there.
-  lto_target_type = "static_library"
-}
-
 symbol_exports("exports") {
   exports_file = "lto.exports"
 }
 
-target(lto_target_type, "lto") {
+shared_library("lto") {
   output_name = "LTO"
   deps = [
+    ":exports",
     "//llvm/lib/Bitcode/Reader",
     "//llvm/lib/IR",
     "//llvm/lib/LTO",
     "//llvm/lib/MC",
     "//llvm/lib/MC/MCDisassembler",
     "//llvm/lib/Support",
     "//llvm/lib/Target",
     "//llvm/lib/Target:TargetsToBuild",
   ]
   sources = [
     "LTODisassembler.cpp",
     "lto.cpp",
   ]
 
-  if (lto_target_type == "shared_library") {
-    deps += [ ":exports" ]
-  }
-
   if (host_os == "mac") {
     ldflags = [
       "-Wl,-compatibility_version,1",
       "-Wl,-current_version,$llvm_version",
 
       # See llvm_setup_rpath() in CMake.
       "-Wl,-install_name,@rpath/libLTO.dylib",
       "-Wl,-rpath,@loader_path/../lib",
     ]
   }
 }