LoopDistribute/LAA: Add tests to catch regressions

[arsenm]

Summary

I broke 2 of these with a patch, but were not covered by existing tests.

[arsenm]

Catch another broken case

[Meinersbur]

As I understand the language reference, ("The optimizers may change the order of volatile operations relative to non-volatile operations.") the loop can be distributed as long as there all volatile operations stay in the same loop. I this is meant to test the current implementation, can you add a comment to make this clear (such as "TODO: distribution of volatile may be possible under some circumstance, but the current implementation does not touch them")

test/Transforms/LoopDistribute/basic-with-memchecks.ll

120–125

This might not sufficiently check that no distribution occured. The br i1 %exitcond does match br i1 %exitcond.ldist1. Is there a guaranteed that the ldist loops are added before the original %for.body/%exitcond pair?

173–174

[nit] To avoid some ambiguity understanding the sentence: "Make sure the loop is not vectorized due to the volatile, even though it has no memory writes"

test/Transforms/LoopVectorize/write-only.ll

27 ↗

(On Diff #203686)

Add comment about what this is supposed to test? Such as "Ensure that volatile stores are not vectorized"

[arsenm]

Address comments, move one test to loop vectorizer

[Meinersbur]

test/Transforms/LoopDistribute/basic-with-memchecks.ll

114

What I meant was adding the TODO here, to avoid the impression that the "no distribution" is a correctness requirement.

[arsenm]

r363158

test/Transforms/LoopDistribute/basic-with-memchecks.ll

 target triple = "x86_64-apple-macosx10.10.0"
 
 @B = common global i32* null, align 8
 @A = common global i32* null, align 8
 @C = common global i32* null, align 8
 @D = common global i32* null, align 8
 @E = common global i32* null, align 8
 
+; CHECK-LABEL: @f(
 define void @f() {
 entry:
   %a = load i32*, i32** @A, align 8
   %b = load i32*, i32** @B, align 8
   %c = load i32*, i32** @C, align 8
   %d = load i32*, i32** @D, align 8
   %e = load i32*, i32** @E, align 8
   br label %for.body
for.body:                                         ; preds = %for.body, %entry
   store i32 %mulC, i32* %arrayidxC, align 4
 
   %exitcond = icmp eq i64 %add, 20
   br i1 %exitcond, label %for.end, label %for.body
 
 for.end:                                          ; preds = %for.body
   ret void
 }
+
+; Make sure there's no "Multiple reports generated" assert with a
+; volatile load, and no distribution
+; CHECK-LABEL: @f_volatile_load(
+; CHECK: br label %for.body
+
+; CHECK-NOT: load
+
+; CHECK: {{^}}for.body:
+; CHECK: load i32
+; CHECK: load i32
+; CHECK: load volatile i32
+; CHECK: load i32
+; CHECK: br i1 %exitcond
+
+; CHECK-NOT: load
+
+; VECTORIZE-NOT: load <4 x i32>
+; VECTORIZE-NOT: mul <4 x i32>
+define void @f_volatile_load() {
+entry:
+  %a = load i32*, i32** @A, align 8
+  %b = load i32*, i32** @B, align 8
+  %c = load i32*, i32** @C, align 8
+  %d = load i32*, i32** @D, align 8
+  %e = load i32*, i32** @E, align 8
+  br label %for.body
+
+for.body:
+  %ind = phi i64 [ 0, %entry ], [ %add, %for.body ]
+
+  %arrayidxA = getelementptr inbounds i32, i32* %a, i64 %ind
+  %loadA = load i32, i32* %arrayidxA, align 4
+
+  %arrayidxB = getelementptr inbounds i32, i32* %b, i64 %ind
+  %loadB = load i32, i32* %arrayidxB, align 4
+
+  %mulA = mul i32 %loadB, %loadA
+
+  %add = add nuw nsw i64 %ind, 1
+  %arrayidxA_plus_4 = getelementptr inbounds i32, i32* %a, i64 %add
+  store i32 %mulA, i32* %arrayidxA_plus_4, align 4
+
+  %arrayidxD = getelementptr inbounds i32, i32* %d, i64 %ind
+  %loadD = load volatile i32, i32* %arrayidxD, align 4
+
+  %arrayidxE = getelementptr inbounds i32, i32* %e, i64 %ind
+  %loadE = load i32, i32* %arrayidxE, align 4
+
+  %mulC = mul i32 %loadD, %loadE
+
+  %arrayidxC = getelementptr inbounds i32, i32* %c, i64 %ind
+  store i32 %mulC, i32* %arrayidxC, align 4
+
+  %exitcond = icmp eq i64 %add, 20
+  br i1 %exitcond, label %for.end, label %for.body
+
+for.end:
+  ret void
+}
+
+; Make sure this isn't treated as vectorizable even though the loop is
+; readonly due to the volatile.
+; CHECK-LABEL: @f_with_volatile_readonly_loop(
+; CHECK: br label %for.body
+
+; CHECK-NOT: load
+
+; CHECK: {{^}}for.body:
+; CHECK: load i32
+; CHECK: load volatile i32
+; CHECK: load i32
+; CHECK: load i32
+; CHECK: br i1 %exitcond
+
+; CHECK-NOT: load
+
+; VECTORIZE-NOT: load <4 x i32>
+; VECTORIZE-NOT: mul <4 x i32>
+define i32 @f_with_volatile_readonly_loop() {
+entry:
+  %a = load i32*, i32** @A, align 8
+  %b = load i32*, i32** @B, align 8
+  %c = load i32*, i32** @C, align 8
+  %d = load i32*, i32** @D, align 8
+  %e = load i32*, i32** @E, align 8
+  br label %for.body
+
+for.body:
+  %ind = phi i64 [ 0, %entry ], [ %add, %for.body ]
+  %sum.phi = phi i32 [ 0, %entry ], [ %sum, %for.body ]
+
+  %arrayidxA = getelementptr inbounds i32, i32* %a, i64 %ind
+  %loadA = load i32, i32* %arrayidxA, align 4
+
+  %arrayidxB = getelementptr inbounds i32, i32* %b, i64 %ind
+  %loadB = load volatile i32, i32* %arrayidxB, align 4
+
+  %mulA = mul i32 %loadB, %loadA
+
+  %add = add nuw nsw i64 %ind, 1
+  %arrayidxA_plus_4 = getelementptr inbounds i32, i32* %a, i64 %add
+  store i32 %mulA, i32* %arrayidxA_plus_4, align 4
+
+  %arrayidxD = getelementptr inbounds i32, i32* %d, i64 %ind
+  %loadD = load i32, i32* %arrayidxD, align 4
+
+  %arrayidxE = getelementptr inbounds i32, i32* %e, i64 %ind
+  %loadE = load i32, i32* %arrayidxE, align 4
+
+  %mulC = mul i32 %loadD, %loadE
+  %sum = add i32 %mulC, %sum.phi
+
+  %exitcond = icmp eq i64 %add, 20
+  br i1 %exitcond, label %for.end, label %for.body
+
+for.end:
+  ret i32 %sum
+}