Adding test cases showing the behavior of LoopUnrollPass according to optnone and optsize attributes

[mamai]

Summary

The unroll pass was disabled by clang in /Os. Those new test cases shows that the pass will behave correctly even if it is not fully disabled. This patch is related to http://reviews.llvm.org/D19827, which would re-enable the pass in /Os.

[mcrosier]

-Please refactor the optsize tests into a single file (e.g., unroll-optsize.ll). If you factored all the test into a single file that would be even better. We want to minimize the number of times opt is invoked.
-Please add a test case for minsize. In this case we don't want to unroll the loop, if I'm not mistaken.

How are we handling -O1? The clang patch D19827 will have a functional change at this optimization level, if I'm not mistaken.

test/Transforms/LoopUnroll/unroll-optnone.ll

19 ↗

(On Diff #55993)

Please add a CHECK-LABEL directive. I.e.,

CHECK-LABEL: @unroll_optnone

test/Transforms/LoopUnroll/unroll-optsize1.ll

19 ↗

(On Diff #55993)

Please add a CHECK-LABEL directive.

test/Transforms/LoopUnroll/unroll-optsize2.ll

18 ↗

(On Diff #55993)

Please add a CHECK-LABEL directive.

[mamai]

• I am not sure it is possible to merge the optsize tests in one call to opt, since one of them use the -unroll-count parameter and not the other. Do you see another way to do that?

• According to a previous commit fixing the behavior of minsize, I think it should behave the same as with optsize. See http://lists.llvm.org/pipermail/llvm-commits/Week-of-Mon-20160111/323952.html.

[mcrosier]

In D19870#420185, @mamai wrote:

• I am not sure it is possible to merge the optsize tests in one call to opt, since one of them use the -unroll-count parameter and not the other. Do you see another way to do that?

You can have multiple RUN lines in a file. To differentiate the runs you can use the FileCheck --check-prefix command.

For example, look at the top of the loop-remarks.ll test in llvm/test/Transforms/LoopUnroll.

Something like:

; RUN: opt < %s -S -loop-unroll  | FileCheck %s
; RUN: opt < %s -S -loop-unroll -unroll-count=4 | FileCheck -check-prefix=UNROLLCOUNT4 %s

By default, FileCheck assumes the prefix is CHECK. Therefore, unroll-optnone.ll and unroll-optsize2.ll can just use the CHECK: directive, while all the CHECK directives in the unroll-optsize1.ll file will be UNROLLCOUNT4:

Hopefully, that all makes sense.

• According to a previous commit fixing the behavior of minsize, I think it should behave the same as with optsize. See http://lists.llvm.org/pipermail/llvm-commits/Week-of-Mon-20160111/323952.html.

In that case, please add a test case with minsize that shows the expected behavior.

I'm still interested to know how loop unroll behaves at -O1.

[mamai]

Ok, thanks! I will modify the test cases and merge them in one file.

For /O1, I think you are right about the clang patch having a functional change. I don't see anything preventing the unrolling to execute in /O1.

[mamai]

• Merged test cases into one file.
• Added a case for minsize.
• Modified the test that shows the behavior of optsize when no unroll factor is specified.

[mcrosier]

lgtm. thanks.

llvm/trunk/test/Transforms/LoopUnroll/unroll-opt-attribute.ll

+; RUN: opt < %s -S -loop-unroll -unroll-count=4 | FileCheck -check-prefix=CHECK_COUNT4 %s
+; RUN: opt < %s -S -loop-unroll | FileCheck -check-prefix=CHECK_NOCOUNT %s
+
+
+;///////////////////// TEST 1 //////////////////////////////
+
+; This test shows that with optsize attribute, the loop is unrolled
+; according to the specified unroll factor.
+
+define void @Test1() nounwind optsize {
+entry:
+  br label %loop
+
+loop:
+  %iv = phi i32 [ 0, %entry ], [ %inc, %loop ]
+  %inc = add i32 %iv, 1
+  %exitcnd = icmp uge i32 %inc, 1024
+  br i1 %exitcnd, label %exit, label %loop
+
+exit:
+  ret void
+}
+
+; CHECK_COUNT4-LABEL: @Test1
+; CHECK_COUNT4:      phi
+; CHECK_COUNT4-NEXT: add
+; CHECK_COUNT4-NEXT: add
+; CHECK_COUNT4-NEXT: add
+; CHECK_COUNT4-NEXT: add
+; CHECK_COUNT4-NEXT: icmp
+
+
+;///////////////////// TEST 2 //////////////////////////////
+
+; This test shows that with minsize attribute, the loop is unrolled
+; according to the specified unroll factor.
+
+define void @Test2() nounwind minsize {
+entry:
+  br label %loop
+
+loop:
+  %iv = phi i32 [ 0, %entry ], [ %inc, %loop ]
+  %inc = add i32 %iv, 1
+  %exitcnd = icmp uge i32 %inc, 1024
+  br i1 %exitcnd, label %exit, label %loop
+
+exit:
+  ret void
+}
+
+; CHECK_COUNT4-LABEL: @Test2
+; CHECK_COUNT4:      phi
+; CHECK_COUNT4-NEXT: add
+; CHECK_COUNT4-NEXT: add
+; CHECK_COUNT4-NEXT: add
+; CHECK_COUNT4-NEXT: add
+; CHECK_COUNT4-NEXT: icmp
+
+
+;///////////////////// TEST 3 //////////////////////////////
+
+; This test shows that with optnone attribute, the loop is not unrolled
+; even if an unroll factor was specified.
+
+define void @Test3() nounwind optnone noinline {
+entry:
+  br label %loop
+
+loop:
+  %iv = phi i32 [ 0, %entry ], [ %inc, %loop ]
+  %inc = add i32 %iv, 1
+  %exitcnd = icmp uge i32 %inc, 1024
+  br i1 %exitcnd, label %exit, label %loop
+
+exit:
+  ret void
+}
+
+; CHECK_COUNT4-LABEL: @Test3
+; CHECK_COUNT4:      phi
+; CHECK_COUNT4-NEXT: add
+; CHECK_COUNT4-NEXT: icmp
+
+
+;///////////////////// TEST 4 //////////////////////////////
+
+; This test shows that without any attribute, this loop is fully unrolled 
+; by default.
+
+@tab = common global [24 x i32] zeroinitializer, align 4
+
+define i32 @Test4() {
+entry:
+  br label %for.body
+
+for.body:                                         ; preds = %for.body, %entry
+  %i.05 = phi i32 [ 0, %entry ], [ %inc, %for.body ]
+  %arrayidx = getelementptr inbounds [24 x i32], [24 x i32]* @tab, i32 0, i32 %i.05
+  store i32 %i.05, i32* %arrayidx, align 4
+  %inc = add nuw nsw i32 %i.05, 1
+  %exitcond = icmp eq i32 %inc, 24
+  br i1 %exitcond, label %for.end, label %for.body
+
+for.end:                                          ; preds = %for.body
+  ret i32 42
+}
+
+; CHECK_NOCOUNT-LABEL: @Test4
+; CHECK_NOCOUNT:      store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: store
+; CHECK_NOCOUNT-NEXT: ret
+
+
+;///////////////////// TEST 5 //////////////////////////////
+
+; This test shows that with optsize attribute, this loop is not unrolled 
+; by default.
+
+define i32 @Test5() optsize {
+entry:
+  br label %for.body
+
+for.body:                                         ; preds = %for.body, %entry
+  %i.05 = phi i32 [ 0, %entry ], [ %inc, %for.body ]
+  %arrayidx = getelementptr inbounds [24 x i32], [24 x i32]* @tab, i32 0, i32 %i.05
+  store i32 %i.05, i32* %arrayidx, align 4
+  %inc = add nuw nsw i32 %i.05, 1
+  %exitcond = icmp eq i32 %inc, 24
+  br i1 %exitcond, label %for.end, label %for.body
+
+for.end:                                          ; preds = %for.body
+  ret i32 42
+}
+
+; CHECK_NOCOUNT-LABEL: @Test5
+; CHECK_NOCOUNT:      phi
+; CHECK_NOCOUNT:      icmp