Added Missing Check Statements for "apint-select.ll" file.

[sonamkumari]

Summary

Hi Suyog,

I have added the missing Check Statements for "apint-select.ll" file.
Please help in reviewing it.

Regards,
Sonam.

[suyog]

There is already CHECK-NOT present which checks if select is eliminated or not.
The objective of this test case was to check if select is eliminated.

I would suggest to refer following link for FileCheck :

http://llvm.org/docs/CommandGuide/FileCheck.html

test/Transforms/InstCombine/apint-select.ll

 ; This test makes sure that these instructions are properly eliminated.
 
 ; RUN: opt < %s -instcombine -S | FileCheck %s
 ; CHECK-NOT: select
 
 
 define i41 @test1(i1 %C) {
   %V = select i1 %C, i41 1, i41 0  ; V = C
   ret i41 %V
+; CHECK-LABEL: @test1(
+; CHECK-NEXT: %V = zext i1 %C to i41
+; CHECK-NEXT: ret i41 %V
 }
 
 define i999 @test2(i1 %C) {
   %V = select i1 %C, i999 0, i999 1  ; V = C
   ret i999 %V
+; CHECK-LABEL: @test2(
+; CHECK-NEXT: %1 = zext i1 %C to i999
+; CHECK-NEXT: %V = xor i999 %1, 1
+; CHECK-NEXT: ret i999 %V
 }
 
 define i41 @test3(i41 %X) {
     ;; (x <s 0) ? -1 : 0 -> ashr x, 31
     %t = icmp slt i41 %X, 0
     %V = select i1 %t, i41 -1, i41 0
     ret i41 %V
+; CHECK-LABEL: @test3(
+; CHECK-NEXT: %X.lobit = ashr i41 %X, 40
+; CHECK-NEXT: ret i41 %X.lobit
 }
 
 define i1023 @test4(i1023 %X) {
     ;; (x <s 0) ? -1 : 0 -> ashr x, 31
     %t = icmp slt i1023 %X, 0
     %V = select i1 %t, i1023 -1, i1023 0
     ret i1023 %V
+; CHECK-LABEL: @test4(
+; CHECK-NEXT: %X.lobit = ashr i1023 %X, 1022
+; CHECK-NEXT: ret i1023 %X.lobit
 }
 
 define i41 @test5(i41 %X) {
     ;; ((X & 27) ? 27 : 0)
     %Y = and i41 %X, 32
     %t = icmp ne i41 %Y, 0
     %V = select i1 %t, i41 32, i41 0
     ret i41 %V
+; CHECK-LABEL: @test5(
+; CHECK-NEXT: %Y = and i41 %X, 32
+; CHECK-NEXT: ret i41 %Y
 }
 
 define i1023 @test6(i1023 %X) {
     ;; ((X & 27) ? 27 : 0)
     %Y = and i1023 %X, 64
     %t = icmp ne i1023 %Y, 0
     %V = select i1 %t, i1023 64, i1023 0
     ret i1023 %V
+; CHECK-LABEL: @test6(
+; CHECK-NEXT: %Y = and i1023 %X, 64
+; CHECK-NEXT: ret i1023 %Y
 }