This is an archive of the discontinued LLVM Phabricator instance.

Differential D55981

[gn build] Add build files for clang, clang-offload-bundler, and clang/lib/Headers
ClosedPublic

Authored by thakis on Dec 20 2018, 7:10 PM.

Details

Reviewers
phosek
Commits
rG6399c5a3ba72: [gn build] Add build files for clang, clang-offload-bundler, and…
rL349991: [gn build] Add build files for clang, clang-offload-bundler, and…
Summary

With this, the GN build can build clang!

Diff Detail

Repository
rL LLVM

Event Timeline

thakis created this revision.Dec 20 2018, 7:10 PM
Herald added a subscriber: jfb. · View Herald TranscriptDec 20 2018, 7:10 PM
thakis added a parent revision: D55980: [gn build] Add build file for clang/lib/FrontendTool.Dec 20 2018, 7:10 PM
thakis added a child revision: D55984: [gn build] Embed __TEXT __info_plist section into clang binary on macOS.Dec 20 2018, 7:38 PM
phosek added inline comments.Dec 21 2018, 2:42 PM
llvm/utils/gn/secondary/clang/lib/Headers/BUILD.gn
6 ↗(On Diff #179234)

Why not just inline this? This variable doesn't seem to be used from anywhere else?

thakis marked 2 inline comments as done.Dec 21 2018, 7:41 PM
thakis added inline comments.
llvm/utils/gn/secondary/clang/lib/Headers/BUILD.gn
6 ↗(On Diff #179234)

Good question. No good reason, done.

thakis updated this revision to Diff 179404.Dec 21 2018, 7:41 PM
thakis marked an inline comment as done.
phosek accepted this revision.Dec 21 2018, 7:50 PM

LGTM

This revision is now accepted and ready to land.Dec 21 2018, 7:50 PM
Closed by commit rL349991: [gn build] Add build files for clang, clang-offload-bundler, and… (authored by nico). · Explain WhyDec 21 2018, 7:53 PM
This revision was automatically updated to reflect the committed changes.
Herald added a subscriber: llvm-commits. · View Herald TranscriptDec 21 2018, 7:53 PM

Revision Contents

PathSize
llvm/
trunk/
utils/
gn/
secondary/
21 lines
clang/
lib/
Headers/
163 lines
tools/
clang-offload-bundler/
13 lines
driver/
72 lines

Diff 179407

llvm/trunk/utils/gn/secondary/BUILD.gn

group("default") { group("default") {
deps = [ deps = [
"//clang/lib/ARCMigrate", ":clang",
"//clang/lib/AST",
"//clang/lib/ASTMatchers",
"//clang/lib/CodeGen",
"//clang/lib/CrossTU",
"//clang/lib/Driver",
"//clang/lib/Frontend",
"//clang/lib/Frontend/Rewrite",
"//clang/lib/FrontendTool",
"//clang/lib/Index",
"//clang/lib/Parse",
"//clang/lib/Serialization",
"//clang/lib/StaticAnalyzer/Checkers",
"//clang/lib/StaticAnalyzer/Core",
"//clang/lib/StaticAnalyzer/Frontend",
"//clang/tools/clang-format", "//clang/tools/clang-format",
"//lld/test", "//lld/test",
"//llvm/tools/llvm-cat", "//llvm/tools/llvm-cat",
"//llvm/tools/llvm-lto", "//llvm/tools/llvm-lto",
"//llvm/tools/llvm-lto2", "//llvm/tools/llvm-lto2",
"//llvm/tools/llvm-modextract", "//llvm/tools/llvm-modextract",
"//llvm/tools/llvm-profdata", "//llvm/tools/llvm-profdata",
"//llvm/tools/llvm-symbolizer:symlinks", "//llvm/tools/llvm-symbolizer:symlinks",
Show All 19 Lines
# targets that need symlinks) even though most links don't need symlinks. # targets that need symlinks) even though most links don't need symlinks.
# Instead, have a top-level target for each target that needs symlinks, and # Instead, have a top-level target for each target that needs symlinks, and
# make that depend on the symlinks. Then the symlinks can depend on the # make that depend on the symlinks. Then the symlinks can depend on the
# executable. This has the effect that `ninja lld` builds lld and then creates # executable. This has the effect that `ninja lld` builds lld and then creates
# symlinks (via this target), while `ninja bin/lld` only builds lld and doesn't # symlinks (via this target), while `ninja bin/lld` only builds lld and doesn't
# update symlinks (in particular, on Windows it doesn't copy the new lld to its # update symlinks (in particular, on Windows it doesn't copy the new lld to its
# new locations). # new locations).
# That seems simpler, more explicit, and good enough. # That seems simpler, more explicit, and good enough.
group("clang") {
deps = [
"//clang/tools/driver:symlinks",
]
}
group("lld") { group("lld") {
deps = [ deps = [
"//lld/tools/lld:symlinks", "//lld/tools/lld:symlinks",
] ]
} }
group("llvm-ar") { group("llvm-ar") {
deps = [ deps = [
"//llvm/tools/llvm-ar:symlinks", "//llvm/tools/llvm-ar:symlinks",
Show All 33 Lines

llvm/trunk/utils/gn/secondary/clang/lib/Headers/BUILD.gn

import("//clang/utils/TableGen/clang_tablegen.gni")
import("//llvm/version.gni")
# Generate arm_neon.h
clang_tablegen("arm_neon") {
args = [ "-gen-arm-neon" ]
td_file = "//clang/include/clang/Basic/arm_neon.td"
output_name = "arm_neon.h"
}
# Generate arm_fp16.h
clang_tablegen("arm_fp16") {
args = [ "-gen-arm-fp16" ]
td_file = "//clang/include/clang/Basic/arm_fp16.td"
output_name = "arm_fp16.h"
}
output_dir = "$root_out_dir/lib/clang/$llvm_version/include"
copy("arm_headers") {
visibility = [ ":Headers" ]
deps = [
":arm_fp16",
":arm_neon",
]
sources = get_target_outputs(":arm_neon") + get_target_outputs(":arm_fp16")
outputs = [
"$output_dir/{{source_file_part}}",
]
}
copy("Headers") {
deps = [
":arm_headers",
]
# Tell `gn format` to not reorder the sources list: Its order matches CMake,
# and the ordering is alphabetical but ignores leading underscores.
# NOSORT
sources = [
"adxintrin.h",
"altivec.h",
"ammintrin.h",
"arm_acle.h",
"armintr.h",
"arm64intr.h",
"avx2intrin.h",
"avx512bwintrin.h",
"avx512bitalgintrin.h",
"avx512vlbitalgintrin.h",
"avx512cdintrin.h",
"avx512vpopcntdqintrin.h",
"avx512dqintrin.h",
"avx512erintrin.h",
"avx512fintrin.h",
"avx512ifmaintrin.h",
"avx512ifmavlintrin.h",
"avx512pfintrin.h",
"avx512vbmiintrin.h",
"avx512vbmivlintrin.h",
"avx512vbmi2intrin.h",
"avx512vlvbmi2intrin.h",
"avx512vlbwintrin.h",
"avx512vlcdintrin.h",
"avx512vldqintrin.h",
"avx512vlintrin.h",
"avx512vpopcntdqvlintrin.h",
"avx512vnniintrin.h",
"avx512vlvnniintrin.h",
"avxintrin.h",
"bmi2intrin.h",
"bmiintrin.h",
"__clang_cuda_builtin_vars.h",
"__clang_cuda_cmath.h",
"__clang_cuda_complex_builtins.h",
"__clang_cuda_device_functions.h",
"__clang_cuda_intrinsics.h",
"__clang_cuda_libdevice_declares.h",
"__clang_cuda_math_forward_declares.h",
"__clang_cuda_runtime_wrapper.h",
"cetintrin.h",
"cldemoteintrin.h",
"clzerointrin.h",
"cpuid.h",
"clflushoptintrin.h",
"clwbintrin.h",
"emmintrin.h",
"f16cintrin.h",
"float.h",
"fma4intrin.h",
"fmaintrin.h",
"fxsrintrin.h",
"gfniintrin.h",
"htmintrin.h",
"htmxlintrin.h",
"ia32intrin.h",
"immintrin.h",
"intrin.h",
"inttypes.h",
"invpcidintrin.h",
"iso646.h",
"limits.h",
"lwpintrin.h",
"lzcntintrin.h",
"mm3dnow.h",
"mmintrin.h",
"mm_malloc.h",
"module.modulemap",
"movdirintrin.h",
"msa.h",
"mwaitxintrin.h",
"nmmintrin.h",
"opencl-c.h",
"pconfigintrin.h",
"pkuintrin.h",
"pmmintrin.h",
"popcntintrin.h",
"prfchwintrin.h",
"ptwriteintrin.h",
"rdseedintrin.h",
"rtmintrin.h",
"s390intrin.h",
"sgxintrin.h",
"shaintrin.h",
"smmintrin.h",
"stdalign.h",
"stdarg.h",
"stdatomic.h",
"stdbool.h",
"stddef.h",
"__stddef_max_align_t.h",
"stdint.h",
"stdnoreturn.h",
"tbmintrin.h",
"tgmath.h",
"tmmintrin.h",
"unwind.h",
"vadefs.h",
"vaesintrin.h",
"varargs.h",
"vecintrin.h",
"vpclmulqdqintrin.h",
"waitpkgintrin.h",
"wbnoinvdintrin.h",
"wmmintrin.h",
"__wmmintrin_aes.h",
"__wmmintrin_pclmul.h",
"x86intrin.h",
"xmmintrin.h",
"xopintrin.h",
"xsavecintrin.h",
"xsaveintrin.h",
"xsaveoptintrin.h",
"xsavesintrin.h",
"xtestintrin.h",
"cuda_wrappers/algorithm",
"cuda_wrappers/complex",
"cuda_wrappers/new",
]
outputs = [
"$output_dir/{{source_target_relative}}",
]
}

llvm/trunk/utils/gn/secondary/clang/tools/clang-offload-bundler/BUILD.gn

executable("clang-offload-bundler") {
configs += [ "//llvm/utils/gn/build:clang_code" ]
deps = [
"//clang/lib/Basic",
"//llvm/lib/Bitcode/Writer",
"//llvm/lib/IR",
"//llvm/lib/Object",
"//llvm/lib/Support",
]
sources = [
"ClangOffloadBundler.cpp",
]
}

llvm/trunk/utils/gn/secondary/clang/tools/driver/BUILD.gn

import("//llvm/utils/gn/build/symlink_or_copy.gni")
symlinks = [
# target_name, symlink_target pairs: GN doesn't support '+' in rule names.
[
"clangxx",
"clang++",
],
[
"clang-cl",
"clang-cl",
],
[
"clang-cpp",
"clang-cpp",
],
]
foreach(target, symlinks) {
symlink_or_copy(target[0]) {
deps = [
":clang",
]
source = "clang"
output = "$root_out_dir/bin/${target[1]}"
}
}
# //:clang depends on this symlink target, see comment in //BUILD.gn.
group("symlinks") {
deps = []
foreach(target, symlinks) {
deps += [ ":${target[0]}" ]
}
}
executable("clang") {
configs += [ "//llvm/utils/gn/build:clang_code" ]
deps = [
"//clang/include/clang/Config",
"//clang/lib/Basic",
"//clang/lib/CodeGen",
"//clang/lib/Driver",
"//clang/lib/Frontend",
"//clang/lib/FrontendTool",
"//clang/lib/Headers",
"//clang/tools/clang-offload-bundler",
"//llvm/include/llvm/Config:llvm-config",
"//llvm/lib/Analysis",
"//llvm/lib/CodeGen",
"//llvm/lib/IR",
"//llvm/lib/MC",
"//llvm/lib/MC/MCParser",
"//llvm/lib/Option",
"//llvm/lib/Support",
"//llvm/lib/Target:TargetsToBuild",
"//llvm/lib/Transforms/IPO",
"//llvm/lib/Transforms/InstCombine",
"//llvm/lib/Transforms/Instrumentation",
"//llvm/lib/Transforms/ObjCARC",
"//llvm/lib/Transforms/Scalar",
"//llvm/lib/Transforms/Utils",
"//llvm/lib/Transforms/Vectorize",
]
sources = [
"cc1_main.cpp",
"cc1as_main.cpp",
"cc1gen_reproducer_main.cpp",
"driver.cpp",
]
# FIXME: Info.plist embedding for mac builds.
}