Index: lib/Target/RISCV/CMakeLists.txt
===================================================================
--- lib/Target/RISCV/CMakeLists.txt
+++ lib/Target/RISCV/CMakeLists.txt
@@ -1,3 +1,10 @@
+set(LLVM_TARGET_DEFINITIONS RISCV.td)
+
+tablegen(LLVM RISCVGenRegisterInfo.inc -gen-register-info)
+tablegen(LLVM RISCVGenInstrInfo.inc -gen-instr-info)
+
+add_public_tablegen_target(RISCVCommonTableGen)
+
 add_llvm_target(RISCVCodeGen
   RISCVTargetMachine.cpp
   )
Index: lib/Target/RISCV/RISCV.td
===================================================================
--- /dev/null
+++ lib/Target/RISCV/RISCV.td
@@ -0,0 +1,27 @@
+//===-- RISCV.td - Describe the RISCV Target Machine -------*- tablegen -*-===//
+//
+//                     The LLVM Compiler Infrastructure
+//
+// This file is distributed under the University of Illinois Open Source
+// License. See LICENSE.TXT for details.
+//
+//===----------------------------------------------------------------------===//
+
+include "llvm/Target/Target.td"
+
+include "RISCVRegisterInfo.td"
+include "RISCVInstrInfo.td"
+
+
+def RISCVInstrInfo : InstrInfo;
+
+def Feature64Bit   : SubtargetFeature<"64bit", "HasRV64", "true",
+                                      "Implements RV64">;
+
+def : ProcessorModel<"RV32I", NoSchedModel, []>;
+
+def : ProcessorModel<"RV64I", NoSchedModel, [Feature64Bit]>;
+
+def RISCV : Target {
+  let InstructionSet = RISCVInstrInfo;
+}
Index: lib/Target/RISCV/RISCVInstrFormats.td
===================================================================
--- /dev/null
+++ lib/Target/RISCV/RISCVInstrFormats.td
@@ -0,0 +1,134 @@
+//===-- RISCVInstrFormats.td - RISCV Instruction Formats ---*- tablegen -*-===//
+//
+//                     The LLVM Compiler Infrastructure
+//
+// This file is distributed under the University of Illinois Open Source
+// License. See LICENSE.TXT for details.
+//
+//===----------------------------------------------------------------------===//
+
+class RISCVInst<dag outs, dag ins, string asmstr, list<dag> pattern>
+    : Instruction {
+  field bits<32> Inst;
+  let Size = 4;
+
+  bits<7> Opcode = 0;
+
+  let Inst{6-0} = Opcode;
+
+  let Namespace = "RISCV";
+
+  dag OutOperandList = outs;
+  dag InOperandList = ins;
+  let AsmString = asmstr;
+  let Pattern = pattern;
+}
+
+// Pseudo instructions
+class Pseudo<dag outs, dag ins, string asmstr, list<dag> pattern>
+    : RISCVInst<outs, ins, asmstr, pattern> {
+  let isPseudo = 1;
+}
+
+class FR<bits<7> opcode, bits<3> funct3, bits<7> funct7, dag outs, dag ins,
+         string asmstr, list<dag> pattern> : RISCVInst<outs, ins, asmstr, pattern>
+{
+  bits<5> rd;
+  bits<5> rs1;
+  bits<5> rs2;
+
+  let Opcode = opcode;
+  let Inst{11-7} = rd;
+  let Inst{14-12} = funct3;
+  let Inst{19-15} = rs1;
+  let Inst{24-20} = rs2;
+  let Inst{31-25} = funct7;
+}
+
+class FI<bits<7> opcode, bits<3> funct3, dag outs, dag ins, string asmstr, list<dag> pattern>
+    : RISCVInst<outs, ins, asmstr, pattern>
+{
+  bits<5> rd;
+  bits<5> rs1;
+  bits<12> imm12;
+
+  let Opcode = opcode;
+  let Inst{11-7} = rd;
+  let Inst{14-12} = funct3;
+  let Inst{19-15} = rs1;
+  let Inst{31-20} = imm12;
+}
+
+class FI32Shift<bits<7> opcode, bits<3> funct3, bit arithshift, dag outs, dag ins, string asmstr, list<dag> pattern>
+    : RISCVInst<outs, ins, asmstr, pattern>
+{
+  bits<5> rd;
+  bits<5> rs1;
+  bits<5> shamt;
+
+  let Opcode = opcode;
+  let Inst{11-7} = rd;
+  let Inst{14-12} = funct3;
+  let Inst{19-15} = rs1;
+  let Inst{24-20} = shamt;
+  let Inst{29-25} = 0;
+  let Inst{30} = arithshift;
+  let Inst{31} = 0;
+}
+
+class FS<bits<7> opcode, bits<3> funct3, dag outs, dag ins, string asmstr, list<dag> pattern>
+    : RISCVInst<outs, ins, asmstr, pattern>
+{
+  bits<12> imm12;
+  bits<5> rs1;
+  bits<5> rs2;
+
+  let Opcode = opcode;
+  let Inst{11-7} = imm12{4-0};
+  let Inst{14-12} = funct3;
+  let Inst{19-15} = rs1;
+  let Inst{24-20} = rs2;
+  let Inst{31-25} = imm12{11-5};
+}
+
+class FSB<bits<7> opcode, bits<3> funct3, dag outs, dag ins, string asmstr, list<dag> pattern>
+    : RISCVInst<outs, ins, asmstr, pattern>
+{
+  bits<13> imm13;
+  bits<5> rs1;
+  bits<5> rs2;
+
+  let Opcode = opcode;
+  let Inst{11-8} = imm13{4-1};
+  let Inst{7} = imm13{11};
+  let Inst{14-12} = funct3;
+  let Inst{19-15} = rs1;
+  let Inst{24-20} = rs2;
+  let Inst{30-25} = imm13{10-5};
+  let Inst{31} = imm13{12};
+}
+
+class FU<bits<7> opcode, dag outs, dag ins, string asmstr, list<dag> pattern>
+    : RISCVInst<outs, ins, asmstr, pattern>
+{
+  bits<20> imm20;
+  bits<5> rd;
+
+  let Opcode = opcode;
+  let Inst{11-7} = rd;
+  let Inst{31-12} = imm20;
+}
+
+class FUJ<bits<7> opcode, dag outs, dag ins, string asmstr, list<dag> pattern>
+    : RISCVInst<outs, ins, asmstr, pattern>
+{
+  bits<21> imm21;
+  bits<5> rd;
+
+  let Opcode = opcode;
+  let Inst{11-7} = rd;
+  let Inst{19-12} = imm21{19-12};
+  let Inst{20} = imm21{11};
+  let Inst{30-21} = imm21{10-1};
+  let Inst{31} = imm21{20};
+}
Index: lib/Target/RISCV/RISCVInstrInfo.td
===================================================================
--- /dev/null
+++ lib/Target/RISCV/RISCVInstrInfo.td
@@ -0,0 +1,47 @@
+//===-- RISCVInstrInfo.td - Target Description for RISCV ---*- tablegen -*-===//
+//
+//                     The LLVM Compiler Infrastructure
+//
+// This file is distributed under the University of Illinois Open Source
+// License. See LICENSE.TXT for details.
+//
+//===----------------------------------------------------------------------===//
+//
+// This file describes the RISC-V instructions in TableGen format.
+//
+//===----------------------------------------------------------------------===//
+
+include "RISCVInstrFormats.td"
+
+def simm12 : Operand<i32>;
+
+class ALU_ri<bits<3> funct3, string OpcodeStr> :
+      FI<0b0010011, funct3, (outs GPR:$rd), (ins GPR:$rs1, simm12:$imm12),
+         !strconcat(OpcodeStr, "\t$rd, $rs1, $imm12"), []>
+{
+}
+
+def ADDI  : ALU_ri<0b000, "addi">;
+def SLTI  : ALU_ri<0b010, "slti">;
+def SLTIU : ALU_ri<0b011, "sltiu">;
+def XORI  : ALU_ri<0b100, "xori">;
+def ORI   : ALU_ri<0b110, "ori">;
+def ANDI  : ALU_ri<0b111, "andi">;
+
+class ALU_rr<bits<3> funct3, bits<7> funct7, string OpcodeStr> :
+      FR<0b0110011, funct3, funct7, (outs GPR:$rd), (ins GPR:$rs1, GPR:$rs2),
+         !strconcat(OpcodeStr, "\t$rd, $rs1, $rs2"), []>
+{
+}
+
+def ADD  : ALU_rr<0b000, 0b0000000, "add">;
+def SUB  : ALU_rr<0b000, 0b0100000, "sub">;
+def SLL  : ALU_rr<0b001, 0b0000000, "sll">;
+def SLT  : ALU_rr<0b010, 0b0000000, "slt">;
+def SLTU : ALU_rr<0b011, 0b0000000, "sltu">;
+def XOR  : ALU_rr<0b100, 0b0000000, "xor">;
+def SRL  : ALU_rr<0b101, 0b0000000, "srl">;
+def SRA  : ALU_rr<0b101, 0b0100000, "sra">;
+def OR   : ALU_rr<0b110, 0b0000000, "or">;
+def AND  : ALU_rr<0b111, 0b0000000, "and">;
+
Index: lib/Target/RISCV/RISCVRegisterInfo.td
===================================================================
--- /dev/null
+++ lib/Target/RISCV/RISCVRegisterInfo.td
@@ -0,0 +1,66 @@
+//===-- RISCVRegisterInfo.td - RISC-V Register defs --------*- tablegen -*-===//
+//
+//                     The LLVM Compiler Infrastructure
+//
+// This file is distributed under the University of Illinois Open Source
+// License. See LICENSE.TXT for details.
+//
+//===----------------------------------------------------------------------===//
+
+//===----------------------------------------------------------------------===//
+//  Declarations that describe the RISC-V register file
+//===----------------------------------------------------------------------===//
+
+let Namespace = "RISCV" in {
+
+// Registers are identified with 5-bit ID numbers.
+// Ri - 64-bit integer registers
+  class Ri<bits<5> Enc, string n, list<string> alt = []> : Register<n> {
+    let HWEncoding{4-0} = Enc;
+    let AltNames = alt;
+  }
+
+  def ABIRegAltName : RegAltNameIndex;
+}
+
+// Integer registers
+let RegAltNameIndices = [ABIRegAltName] in {
+  def X0    : Ri<0, "x0", ["zero"]>, DwarfRegNum<[0]>;
+  def X1    : Ri<1, "x1", ["ra"]>, DwarfRegNum<[1]>;
+  def X2    : Ri<2, "x2", ["sp"]>, DwarfRegNum<[2]>;
+  def X3    : Ri<3, "x3", ["gp"]>, DwarfRegNum<[3]>;
+  def X4    : Ri<4, "x4", ["tp"]>, DwarfRegNum<[4]>;
+  def X5    : Ri<5, "x5", ["t0"]>, DwarfRegNum<[5]>;
+  def X6    : Ri<6, "x6", ["t1"]>, DwarfRegNum<[6]>;
+  def X7    : Ri<7, "x7", ["t2"]>, DwarfRegNum<[7]>;
+  def X8    : Ri<8, "x8", ["s0"]>, DwarfRegNum<[8]>;
+  def X9    : Ri<9, "x9", ["s1"]>, DwarfRegNum<[9]>;
+  def X10   : Ri<10,"x10", ["a0"]>, DwarfRegNum<[10]>;
+  def X11   : Ri<11,"x11", ["a1"]>, DwarfRegNum<[11]>;
+  def X12   : Ri<12,"x12", ["a2"]>, DwarfRegNum<[12]>;
+  def X13   : Ri<13,"x13", ["a3"]>, DwarfRegNum<[13]>;
+  def X14   : Ri<14,"x14", ["a4"]>, DwarfRegNum<[14]>;
+  def X15   : Ri<15,"x15", ["a5"]>, DwarfRegNum<[15]>;
+  def X16   : Ri<16,"x16", ["a6"]>, DwarfRegNum<[16]>;
+  def X17   : Ri<17,"x17", ["a7"]>, DwarfRegNum<[17]>;
+  def X18   : Ri<18,"x18", ["s2"]>, DwarfRegNum<[18]>;
+  def X19   : Ri<19,"x19", ["s3"]>, DwarfRegNum<[19]>;
+  def X20   : Ri<20,"x20", ["s4"]>, DwarfRegNum<[20]>;
+  def X21   : Ri<21,"x21", ["s5"]>, DwarfRegNum<[21]>;
+  def X22   : Ri<22,"x22", ["s6"]>, DwarfRegNum<[22]>;
+  def X23   : Ri<23,"x23", ["s7"]>, DwarfRegNum<[23]>;
+  def X24   : Ri<24,"x24", ["s8"]>, DwarfRegNum<[24]>;
+  def X25   : Ri<25,"x25", ["s9"]>, DwarfRegNum<[25]>;
+  def X26   : Ri<26,"x26", ["s10"]>, DwarfRegNum<[26]>;
+  def X27   : Ri<27,"x27", ["s11"]>, DwarfRegNum<[27]>;
+  def X28   : Ri<28,"x28", ["t3"]>, DwarfRegNum<[28]>;
+  def X29   : Ri<29,"x29", ["t4"]>, DwarfRegNum<[29]>;
+  def X30   : Ri<30,"x30", ["t5"]>, DwarfRegNum<[30]>;
+  def X31   : Ri<31,"x31", ["t6"]>, DwarfRegNum<[31]>;
+}
+
+def GPR : RegisterClass<"RISCV", [i64], 64, (add
+  (sequence "X%u", 0, 31)
+)>;
+
+def GPR32 : RegisterClass<"RISCV", [i32], 32, (add GPR)>;