[gn build] Use lib_dirs instead of putting a qualified path in libs for diaguids.lib

[thakis]

Summary

Follow-up to D109708: Using lib_dirs means this will work with ancient gn binaries.

Change the toolchain definitions to make lib_dirs have the right effect, and
pull out lib_switch of each of the tools while here.

This means we now do pass /LIBPATH: to link.exe, but since we invoke it directly
and not through clang-cl, this doesn't actually require D109624. And since this
is built in to GN, we don't need a config to push the flag to dependents.

This is arguably a bit more idiomatic, and it doesn't require folks to upload
their GN binaries. No effective behavior change.

[hans]

lgtm

Commit message nit:

This is arguably a bit more idiomatic, and it doesn't require folks to upload

s/upload/update/

llvm/utils/gn/build/toolchain/BUILD.gn

if (current_os == "ios" || current_os == "mac") {
       # (https://crbug.com/gn/183), so 1709 is the true minimum enforced by
       # this construct, and if gn_version is not available, this line will still
       # be blamed, making the resolution somewhat discoverable.
       assert(gn_version >= 1693,
              "Your GN is too old! " +
                  "Update it, perhaps by running llvm/utils/gn/get.py")
     }
 
+    # Make these apply to all tools below.
+    lib_switch = "-l"
+    lib_dir_switch = "-L"
+
     tool("solink") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
       if (current_os == "ios" || current_os == "mac") {
         command = "$ld -shared {{ldflags}} -o $outfile {{inputs}} {{libs}} {{frameworks}}"
         default_output_extension = ".dylib"
       } else {
         command = "$ld -shared {{ldflags}} -Wl,-z,defs -Wl,-soname,{{target_output_name}}{{output_extension}} -o $outfile {{inputs}} {{libs}}"
         default_output_extension = ".so"
       }
       description = "SOLINK $outfile"
       outputs = [ outfile ]
-      lib_switch = "-l"
       output_prefix = "lib"
       default_output_dir = "{{root_out_dir}}/lib"
     }
 
     tool("solink_module") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
       if (current_os == "ios" || current_os == "mac") {
         command = "$ld -shared {{ldflags}} -Wl,-flat_namespace -Wl,-undefined,suppress -o $outfile {{inputs}} {{libs}} {{frameworks}}"
         default_output_extension = ".dylib"
       } else {
         command = "$ld -shared {{ldflags}} -Wl,-soname,{{target_output_name}}{{output_extension}} -o $outfile {{inputs}} {{libs}}"
         default_output_extension = ".so"
       }
       description = "SOLINK $outfile"
       outputs = [ outfile ]
-      lib_switch = "-l"
       default_output_dir = "{{root_out_dir}}/lib"
     }
 
     tool("link") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
       if (current_os == "ios" || current_os == "mac") {
         command =
             "$ld {{ldflags}} -o $outfile {{inputs}} {{libs}} {{frameworks}}"
       } else {
         command = "$ld {{ldflags}} -o $outfile -Wl,--start-group {{inputs}} -Wl,--end-group {{libs}}"
       }
       description = "LINK $outfile"
       outputs = [ outfile ]
-      lib_switch = "-l"
 
       # Setting this allows targets to override the default executable output by
       # setting output_dir.
       default_output_dir = "{{root_out_dir}}/bin"
     }
 
     copy_command = "ln -f {{source}} {{output}} 2>/dev/null || (rm -rf {{output}} && cp -af {{source}} {{output}})"
     tool("copy") {
toolchain(target_name) {
 
     tool("alink") {
       command = "$link /lib /nologo {{arflags}} /out:{{output}} {{inputs}}"
       description = "LIB {{output}}"
       outputs = [ "{{output_dir}}/{{target_output_name}}.lib" ]
       default_output_dir = "{{root_out_dir}}/lib"
     }
 
+    # Make these apply to all tools below.
+    lib_switch = ""
+    lib_dir_switch = "/LIBPATH:"
+
     tool("solink") {
       outprefix = "{{output_dir}}/{{target_output_name}}"
       dllfile = "$outprefix{{output_extension}}"
       libfile = "$outprefix.lib"
       pdbfile = "$outprefix.pdb"
       command = "$link /nologo /dll {{ldflags}} /out:$dllfile /implib:$libfile /pdb:$pdbfile {{inputs}} {{libs}} "
       description = "LINK $dllfile"
       link_output = libfile
       depend_output = libfile
       runtime_outputs = [ dllfile ]
       outputs = [
         dllfile,
         libfile,
       ]
-      lib_switch = ""
       default_output_extension = ".dll"
       restat = true
 
       # Put dlls next to the executables in bin/ on Windows, since Windows
       # doesn't have a configurable rpath. This matches initialization of
       # module_dir to bin/ in AddLLVM.cmake's set_output_directory().
       default_output_dir = "{{root_out_dir}}/bin"
     }
 
     # Plugins for opt and clang and so on don't work in LLVM's Windows build
     # since the code doesn't have export annotations, but there are a few
     # standalone loadable modules used for unit-testing LLVM's dynamic library
     # loading code.
     tool("solink_module") {
       outprefix = "{{output_dir}}/{{target_output_name}}"
       dllfile = "$outprefix{{output_extension}}"
       pdbfile = "$outprefix.pdb"
       command = "$link /nologo /dll {{ldflags}} /out:$dllfile /pdb:$pdbfile {{inputs}} {{libs}} "
       description = "LINK_MODULE $dllfile"
       outputs = [ dllfile ]
-      lib_switch = ""
       runtime_outputs = outputs
       default_output_extension = ".dll"
 
       # No default_output_dir, all clients set output_dir.
     }
 
     tool("link") {
       outprefix = "{{output_dir}}/{{target_output_name}}"
       outfile = "$outprefix{{output_extension}}"
       pdbfile = "$outprefix.pdb"
       command = "$link /nologo {{ldflags}} /out:$outfile /pdb:$pdbfile {{inputs}} {{libs}}"
       description = "LINK $outfile"
       outputs = [ outfile ]
-      lib_switch = ""
       default_output_extension = ".exe"
 
       # Setting this allows targets to override the default executable output by
       # setting output_dir.
       default_output_dir = "{{root_out_dir}}/bin"
     }
 
     tool("copy") {

llvm/utils/gn/secondary/llvm/lib/DebugInfo/PDB/BUILD.gn

sources += [
       "DIA/DIASectionContrib.cpp",
       "DIA/DIASession.cpp",
       "DIA/DIASourceFile.cpp",
       "DIA/DIATable.cpp",
     ]
 
     dia_lib_path = ""
     if (sysroot != "") {
-      assert(gn_version >= 1937,
-             "Building with sysroot and DIA requires a newer GN. " +
-                 "Run `python3 llvm\utils\gn\get.py` to update.")
       include_dirs = [ "$sysroot/DIA SDK/include" ]
-      dia_lib_path = "$sysroot/DIA SDK/lib/"  # x86 .lib file is here.
-      if (current_cpu == "arm") {
-        dia_lib_path += "arm/"
+      dia_lib_path = "$sysroot/DIA SDK/lib"  # x86 .lib file is here.
+      if (current_cpu == "/arm") {
+        dia_lib_path += "arm"
       } else if (current_cpu == "arm64") {
-        dia_lib_path += "arm64/"
+        dia_lib_path += "/arm64"
       } else if (current_cpu == "x64") {
-        dia_lib_path += "amd64/"
+        dia_lib_path += "/amd64"
       }
+      lib_dirs = [ dia_lib_path ]
     }
-    libs = [ "${dia_lib_path}diaguids.lib" ]
+    libs = [ "diaguids.lib" ]
   }
 }